|
Subject:
|
OPEN A FILE DIALOG IN MS ACCESS 2000
|
|
Posted By:
|
DevineRule
|
Post Date:
|
11/12/2004 9:14:33 PM
|
HI FOLKS
CAN ANY ONE PLEASE TELL ME HOW TO OPEN AN "OPEN FILE DIALOG" USING VB CODE OR ANY OTHER WAY IN MS ACCESS 2000.
|
|
Reply By:
|
charul_shukla
|
Reply Date:
|
11/16/2004 2:34:26 AM
|
Browse the following links
http://www.experts-exchange.com/Programming/Programming_Languages/Dot_Net/Q_20815889.html
http://support.microsoft.com/default.aspx?scid=kb;en-us;824272&Product=off2003
http://support.microsoft.com/kb/279508
Charul Shukla
|
|
Reply By:
|
Durgeshm
|
Reply Date:
|
6/4/2008 3:48:57 PM
|
Hi,
For Open Box you can use following code:
Private Sub Command0_Click()
Dim strFilter As String
Dim strInputFileName As String
strFilter = ahtAddFilterItem(strFilter, "Access Files (*.mdb)", "*.MDB")
strInputFileName = ahtCommonFileOpenSave(Filter:=strFilter, OpenFile:=True, InitialDir:="", _
DialogTitle:="Please select 007_Datenbank...", _
Flags:=ahtOFN_HIDEREADONLY)
End Sub
This will open a dilogue box for .mde file.
You can edit the same for .xls or other file extentions.
But if you are planing to import that file in your database than you need to write additional codes for the same.
I can give you a sample code which you may edit:
I wanted to import File named as "CHANNEL ASSIGNMENT (Dont replace or rename this file)" from some database in my L:/ drive to my table
"009_CHANNEL ASSIGNMENT (Dont replace or rename this file)" in my current working database. I also specified which columns to be copied in which. Code works very smoothly if tables are not renamed.
Write this code in a button:
If MsgBox("Existing Table will be Deleted. Do You wish to continue?", 1) = 1 Then
Dim strFilter As String
Dim strInputFileName As String
strFilter = ahtAddFilterItem(strFilter, "Access Files (*.mdb)", "*.MDB")
strInputFileName = ahtCommonFileOpenSave(Filter:=strFilter, OpenFile:=True, InitialDir:="", _
DialogTitle:="Please select 009_CHANNEL ASSIGNMENT (Dont replace or rename this file)...", _
Flags:=ahtOFN_HIDEREADONLY)
If Right(strInputFileName, 4) = ".mdb" = False Then
End
End If
If TabVorhanden("009_CHANNEL ASSIGNMENT (Dont replace or rename this file)") = True Then
DoCmd.Echo True, "Deleting temporary 009_CHANNEL ASSIGNMENT (Dont replace or rename this file)..."
DoCmd.DeleteObject acTable, "009_CHANNEL ASSIGNMENT (Dont replace or rename this file)"
End If
DoCmd.TransferDatabase acImport, "Microsoft Access", strInputFileName, acTable, "009_CHANNEL ASSIGNMENT (Dont replace or rename this file)", "009_CHANNEL ASSIGNMENT (Dont replace or rename this file)"
Dim AKTUELLEDB As Database, i As Recordset, W As Recordset
Set AKTUELLEDB = DBEngine(0)(0)
Set i = AKTUELLEDB.OpenRecordset("009_CHANNEL ASSIGNMENT (Dont replace or rename this file)", DB_OPEN_SNAPSHOT)
Set W = AKTUELLEDB.OpenRecordset("CHANNEL ASSIGNMENT (Dont replace or rename this file)", DB_OPEN_DYNASET)
Dim i_int As Integer
DoCmd.SetWarnings False
DoCmd.RunSQL "DELETE * FROM [CHANNEL ASSIGNMENT (Dont replace or rename this file)];"
DoCmd.SetWarnings True
DoCmd.Echo True, "Converting 009_CHANNEL ASSIGNMENT (Dont replace or rename this file) in CHANNEL ASSIGNMENT (Dont replace or rename this file)..."
i.MoveFirst
Do
W.AddNew
W![KKS] = i![KKS]
W![Signal Name] = i![Signal Name]
W![CABINET] = i![CABINET]
W![Channel] = i![Channel]
W![REDUNDANCY] = i![REDUNDANCY]
W![STD HARDWARE PLAN] = i![STD HARDWARE PLAN]
W.Update
i.MoveNext
Loop While i.EOF = False
i.Close
W.Close
DoCmd.Echo True, "Transfering Database to " & strInputFileName & "..."
DoCmd.TransferDatabase acExport, "Microsoft Access", strInputFileName, acTable, "CHANNEL ASSIGNMENT (Dont replace or rename this file)", "CHANNEL ASSIGNMENT (Dont replace or rename this file)"
'DoCmd.OpenTable "CHANNEL ASSIGNMENT (Dont replace or rename this file)", acViewNormal
'DoCmd.Maximize
If TabVorhanden("009_CHANNEL ASSIGNMENT (Dont replace or rename this file)") = True Then
DoCmd.Echo True, "Deleting temporary 009_CHANNEL ASSIGNMENT (Dont replace or rename this file)..."
DoCmd.DeleteObject acTable, "009_CHANNEL ASSIGNMENT (Dont replace or rename this file)"
End If
MsgBox "Conversion ready! Database transfered to '" & strInputFileName & "'.", vbInformation
End
End If
Also with this you will need to define above variables, make two modules named : "Open/Save Dialog box" and "Dienstprogramme"
For "Open/Save Dialog box" Past foll code without editing:
Option Compare Database
Option Explicit
Type tagOPENFILENAME
lStructSize As Long
hwndOwner As Long
hInstance As Long
strFilter As String
strCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
strFile As String
nMaxFile As Long
strFileTitle As String
nMaxFileTitle As Long
strInitialDir As String
strTitle As String
Flags As Long
nFileOffset As Integer
nFileExtension As Integer
strDefExt As String
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type
Declare Function aht_apiGetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" (OFN As tagOPENFILENAME) As Boolean
Declare Function aht_apiGetSaveFileName Lib "comdlg32.dll" _
Alias "GetSaveFileNameA" (OFN As tagOPENFILENAME) As Boolean
Declare Function CommDlgExtendedError Lib "comdlg32.dll" () As Long
Global Const ahtOFN_READONLY = &H1
Global Const ahtOFN_OVERWRITEPROMPT = &H2
Global Const ahtOFN_HIDEREADONLY = &H4
Global Const ahtOFN_NOCHANGEDIR = &H8
Global Const ahtOFN_SHOWHELP = &H10
' You won't use these.
'Global Const ahtOFN_ENABLEHOOK = &H20
'Global Const ahtOFN_ENABLETEMPLATE = &H40
'Global Const ahtOFN_ENABLETEMPLATEHANDLE = &H80
Global Const ahtOFN_NOVALIDATE = &H100
Global Const ahtOFN_ALLOWMULTISELECT = &H200
Global Const ahtOFN_EXTENSIONDIFFERENT = &H400
Global Const ahtOFN_PATHMUSTEXIST = &H800
Global Const ahtOFN_FILEMUSTEXIST = &H1000
Global Const ahtOFN_CREATEPROMPT = &H2000
Global Const ahtOFN_SHAREAWARE = &H4000
Global Const ahtOFN_NOREADONLYRETURN = &H8000
Global Const ahtOFN_NOTESTFILECREATE = &H10000
Global Const ahtOFN_NONETWORKBUTTON = &H20000
Global Const ahtOFN_NOLONGNAMES = &H40000
' New for Windows 95
Global Const ahtOFN_EXPLORER = &H80000
Global Const ahtOFN_NODEREFERENCELINKS = &H100000
Global Const ahtOFN_LONGNAMES = &H200000
Function TestIt()
Dim strFilter As String
Dim lngFlags As Long
strFilter = ahtAddFilterItem(strFilter, "Access Files (*.mda, *.mdb)", _
"*.MDA;*.MDB")
strFilter = ahtAddFilterItem(strFilter, "dBASE Files (*.dbf)", "*.DBF")
strFilter = ahtAddFilterItem(strFilter, "Text Files (*.txt)", "*.TXT")
strFilter = ahtAddFilterItem(strFilter, "All Files (*.*)", "*.*")
MsgBox "You selected: " & ahtCommonFileOpenSave(InitialDir:="C:\", _
Filter:=strFilter, FilterIndex:=3, Flags:=lngFlags, _
DialogTitle:="Hello! Open Me!")
' Since you passed in a variable for lngFlags,
' the function places the output flags value in the variable.
Debug.Print Hex(lngFlags)
End Function
Function GetOpenFile(Optional varDirectory As Variant, _
Optional varTitleForDialog As Variant) As Variant
' Here's an example that gets an Access database name.
Dim strFilter As String
Dim lngFlags As Long
Dim varFileName As Variant
' Specify that the chosen file must already exist,
' don't change directories when you're done
' Also, don't bother displaying
' the read-only box. It'll only confuse people.
lngFlags = ahtOFN_FILEMUSTEXIST Or _
ahtOFN_HIDEREADONLY Or ahtOFN_NOCHANGEDIR
If IsMissing(varDirectory) Then
varDirectory = ""
End If
If IsMissing(varTitleForDialog) Then
varTitleForDialog = ""
End If
' Define the filter string and allocate space in the "c"
' string Duplicate this line with changes as necessary for
' more file templates.
strFilter = ahtAddFilterItem(strFilter, _
"Access (*.mdb)", "*.MDB;*.MDA")
' Now actually call to get the file name.
varFileName = ahtCommonFileOpenSave( _
OpenFile:=True, _
InitialDir:=varDirectory, _
Filter:=strFilter, _
Flags:=lngFlags, _
DialogTitle:=varTitleForDialog)
If Not IsNull(varFileName) Then
varFileName = TrimNull(varFileName)
End If
GetOpenFile = varFileName
End Function
Function ahtCommonFileOpenSave( _
Optional ByRef Flags As Variant, _
Optional ByVal InitialDir As Variant, _
Optional ByVal Filter As Variant, _
Optional ByVal FilterIndex As Variant, _
Optional ByVal DefaultExt As Variant, _
Optional ByVal FileName As Variant, _
Optional ByVal DialogTitle As Variant, _
Optional ByVal hWnd As Variant, _
Optional ByVal OpenFile As Variant) As Variant
' This is the entry point you'll use to call the common
' file open/save dialog. The parameters are listed
' below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem. See examples.
' FilterIndex: 1-based integer indicating which filter
' set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one.
' Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename
Dim OFN As tagOPENFILENAME
Dim strFileName As String
Dim strFileTitle As String
Dim fResult As Boolean
' Give the dialog a caption title.
If IsMissing(InitialDir) Then InitialDir = CurDir
If IsMissing(Filter) Then Filter = ""
If IsMissing(FilterIndex) Then FilterIndex = 1
If IsMissing(Flags) Then Flags = 0&
If IsMissing(DefaultExt) Then DefaultExt = ""
If IsMissing(FileName) Then FileName = ""
If IsMissing(DialogTitle) Then DialogTitle = ""
If IsMissing(hWnd) Then hWnd = Application.hWndAccessApp
If IsMissing(OpenFile) Then OpenFile = True
' Allocate string space for the returned strings.
strFileName = Left(FileName & String(256, 0), 256)
strFileTitle = String(256, 0)
' Set up the data structure before you call the function
With OFN
.lStructSize = Len(OFN)
.hwndOwner = hWnd
.strFilter = Filter
.nFilterIndex = FilterIndex
.strFile = strFileName
.nMaxFile = Len(strFileName)
.strFileTitle = strFileTitle
.nMaxFileTitle = Len(strFileTitle)
.strTitle = DialogTitle
.Flags = Flags
.strDefExt = DefaultExt
.strInitialDir = InitialDir
' Didn't think most people would want to deal with
' these options.
.hInstance = 0
.strCustomFilter = ""
.nMaxCustFilter = 0
.lpfnHook = 0
'New for NT 4.0
.strCustomFilter = String(255, 0)
.nMaxCustFilter = 255
End With
' This will pass the desired data structure to the
' Windows API, which will in turn it uses to display
' the Open/Save As Dialog.
If OpenFile Then
fResult = aht_apiGetOpenFileName(OFN)
Else
fResult = aht_apiGetSaveFileName(OFN)
End If
' The function call filled in the strFileTitle member
' of the structure. You'll have to write special code
' to retrieve that if you're interested.
If fResult Then
' You might care to check the Flags member of the
' structure to get information about the chosen file.
' In this example, if you bothered to pass in a
' value for Flags, we'll fill it in with the outgoing
' Flags value.
If Not IsMissing(Flags) Then Flags = OFN.Flags
ahtCommonFileOpenSave = TrimNull(OFN.strFile)
Else
ahtCommonFileOpenSave = "NoFile"
End If
End Function
Function ahtAddFilterItem(strFilter As String, _
strDescription As String, Optional varItem As Variant) As String
' Tack a new chunk onto the file filter.
' That is, take the old value, stick onto it the description,
' (like "Databases"), a null character, the skeleton
' (like "*.mdb;*.mda") and a final null character.
If IsMissing(varItem) Then varItem = "*.*"
ahtAddFilterItem = strFilter & _
strDescription & vbNullChar & _
varItem & vbNullChar
End Function
Private Function TrimNull(ByVal strItem As String) As String
Dim intPos As Integer
intPos = InStr(strItem, vbNullChar)
If intPos > 0 Then
TrimNull = Left(strItem, intPos - 1)
Else
TrimNull = strItem
End If
End Function
And for "Dienstprogramme" module past:
Function TabVorhanden(Tabellenname As String) As Boolean
Dim db As DAO.Database
Dim tdf As DAO.TableDef
Set db = CurrentDb
For Each tdf In db.TableDefs
If tdf.Name = Tabellenname Then TabVorhanden = True: Exit For
Next
End Function
Thats it offf... Huge thing for just importing some silly data, but its necessary...
Hope it works for you. Do let me know.
Regards,
Durgesh
|
