Hiya

I'm using some code that allows me to browse for an image on my hard drive, click upload and this then uploads my image to a specified folder on my website. This image name then gets placed into a field on an insert page which is then entered into a database.

The front end of my site calls this data from the database and displays the corresponding image for a particular record. However, I need to make sure that the image that's uploaded is the correct width.

Is it possible, before my image is uploaded to the specified folder, that this image can be cropped so that it's exactly the right size. I need to be able to specify the width, but the height can vary (as some images may be square, whilst others may be rectangular portrait).

Can this be done with a bit of ASP code?

Thanks in advance.

Lucy Robinson

Do you mean that you want to resize to your specified size? I don't imagine you really mean to crop it. I have some code that does this very thing, let me dig it up and I'll post it.

Peter
----------------------------------------
Work smarter, not harder.

Using the System.Drawing classes you can do all sorts of image processing. Here's a class file I wrote for an image browser application. I figured the whole thing would be useful for you.
Public Class ImageTools

    Private Enum ResizeType
        PixelFixed
        PixelMax
        Percent
    End Enum

    Private Enum ResizeOp
        Thumbnail
        Bitmap
    End Enum

    Public Class Thumbnail

        Public Shared Function ToMaxDimensions(ByVal image As System.Drawing.Image, ByVal maxHeight As Integer, ByVal maxWidth As Integer) As System.Drawing.Image
            Return DoResize(image, ResizeType.PixelMax, maxHeight, maxWidth, ResizeOp.Thumbnail)
        End Function

        Public Shared Function ToSize(ByVal image As System.Drawing.Image, ByVal height As Integer, ByVal width As Integer) As System.Drawing.Image
            Return DoResize(image, ResizeType.PixelFixed, height, width, ResizeOp.Thumbnail)
        End Function

        Public Shared Function ToPercent(ByVal image As System.Drawing.Image, ByVal percent As Byte) As System.Drawing.Image
            Return DoResize(image, ResizeType.Percent, percent, percent, ResizeOp.Thumbnail)
        End Function

    End Class

    Public Class Resize

        Public Shared Function ToMaxDimensions(ByVal image As System.Drawing.Image, ByVal maxHeight As Integer, ByVal maxWidth As Integer) As System.Drawing.Image
            Return DoResize(image, ResizeType.PixelMax, maxHeight, maxWidth, ResizeOp.Bitmap)
        End Function

        Public Shared Function ToSize(ByVal image As System.Drawing.Image, ByVal height As Integer, ByVal width As Integer) As System.Drawing.Image
            Return DoResize(image, ResizeType.PixelFixed, height, width, ResizeOp.Bitmap)
        End Function

        Public Shared Function ToPercent(ByVal image As System.Drawing.Image, ByVal percent As Byte) As System.Drawing.Image
            Return DoResize(image, ResizeType.Percent, percent, percent, ResizeOp.Bitmap)
        End Function

    End Class

    Private Shared Function DoResize(ByVal objImage As System.Drawing.Image, ByVal eType As ResizeType, ByVal nTargetHeight As Integer, ByVal nTargetWidth As Integer, ByVal eResizeOp As ResizeOp) As System.Drawing.Image
        Dim nCurrentHeight As Integer
        Dim nCurrentWidth As Integer
        Dim nNewHeight As Integer
        Dim nNewWidth As Integer
        Dim objAdjustedImage As System.Drawing.Image

        nCurrentHeight = objImage.Height
        nCurrentWidth = objImage.Width

        Select Case eType
            Case ResizeType.Percent
                nNewHeight = CType(nCurrentHeight * (nTargetHeight / 100), Integer)
                nNewWidth = CType(nCurrentWidth * (nTargetWidth / 100), Integer)

            Case ResizeType.PixelFixed
                nNewHeight = nTargetHeight
                nNewWidth = nTargetWidth

            Case ResizeType.PixelMax
                Select Case True
                    Case nCurrentHeight = nCurrentWidth
                        nNewHeight = System.Math.Max(nTargetHeight, nTargetWidth)
                        nNewWidth = nNewHeight
                    Case nCurrentHeight > nCurrentWidth
                        nNewHeight = nTargetHeight
                        nNewWidth = CType(nCurrentWidth * (nNewHeight / nCurrentHeight), Integer)
                    Case nCurrentWidth > nCurrentHeight
                        nNewWidth = nTargetWidth
                        nNewHeight = CType(nCurrentHeight * (nNewWidth / nCurrentWidth), Integer)
                End Select

        End Select
        If nNewHeight >= nCurrentHeight And nNewWidth >= nCurrentWidth Then
            objAdjustedImage = objImage
        Else
            Select Case eResizeOp
                Case ResizeOp.Bitmap
                    objAdjustedImage = New Bitmap(objImage, nNewWidth, nNewHeight)
                Case ResizeOp.Thumbnail
                    objAdjustedImage = objImage.GetThumbnailImage(nNewWidth, nNewHeight, Nothing, IntPtr.Zero)
            End Select
        End If

        Return objAdjustedImage
    End Function

End Class

Peter
----------------------------------------
Work smarter, not harder.

Cheers for all your help Peter - and thanks for the code - I think it's gonna be extremely useful :)

Lucy

Hi Peter.

That code looks very useful but is it not ASP.NET and not classic ASP?
While I know only VBScript and JScript for classic ASP, this looks alot like VB. I would like to use your code and I've got .NET, but how do I implement it in a classic ASP site?
Perhaps like this:

<%
Dim objImageTools
Set objImageTools = New ImageTools
...

Regards - Jon

Wow.. now I feel like an idiot. I replied to this topic without even noticing it was the ASP forum, not an ASP.Net one!

Because these methods take and return .Net objects, you wouldn't be able to use them directly in class ASP.

HOWEVER!... ;)

With some modifications, one might be able to change the methods to handle simpler arrays that hold the binary data of an image, then you could compile this code in a .Net assembly that was set up to register for COM interop. Then you could use it in classic asp. (this is all just theoretical of course. :D)

Peter
------------------------------------------------------
Work smarter, not harder.

I think I just stick to serverobjects.com :D
Regards - Jon

Cropping images online has come a long way since....

Here's an article on how to crop images using javascript and ASP

http://www.imagecowboy.com/articles/...javascript.asp

live hard, live wide, live long and don't regret

i think this component can help you:
http://i-load.radactive.com/