cdosys email issue

futurehype · October 18th, 2009, 05:58 PM

Hi there, just got involved in coding(ish) and am strugling through. I'm a designer by trade so all of the technical stuff is tough. So please be patient with me as this may hopefully very easy to fix. Basically I'm getting this error from my forgoten password

Microsoft VBScript runtime error '800a01c2'

Wrong number of arguments or invalid property assignment: 'SendEmail'

/forgotten_password.asp, line 27

This is the code without the details which I know are correct as I've tested them via a test page

<%@LANGUAGE="VBSCRIPT" CODEPAGE="1252"%>

<%
Dim UsersRS__value
UsersRS__value = "0"
If (Request("Email") <> "") Then
UsersRS__value = Request("Email")
End If
%>
<%
Dim UsersRS
Dim UsersRS_numRows
Set UsersRS = Server.CreateObject("ADODB.Recordset")
UsersRS.ActiveConnection = MM_mydb_STRING
UsersRS.Source = "SELECT * FROM Customers WHERE CustomerEmail='" + Replace(UsersRS__value, "'", "''") + "' "
UsersRS.CursorType = 0
UsersRS.CursorLocation = 2
UsersRS.LockType = 3
UsersRS.Open()
UsersRS_numRows = 0
%>
<%
if Request("Selected") <> "" then
UserEmail=Request("Email")
if not UsersRS.eof then
UserPassword=UsersRS("CustomerPassword")
SendEmail
Response.Redirect "forgotten_password.asp?success=true"
else
end if
end if
function SendEmail(c)
Set objMail = Server.CreateObject("CDO.Message")
'This section provides the configuration information for the remote SMTP server.

objMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 'Send the message using the network (SMTP over the network).
objMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") ="intmail"
objMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False 'Use SSL for the connection (True or False)
objMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

' If your server requires outgoing authentication uncomment the lines below and use a valid email address and password.
objMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 'basic (clear-text) authentication
objMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") ="websales@******.co.uk"
objMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") ="*****"

objMail.Configuration.Fields.Update

'End remote SMTP server configuration section==

objMail.From = "websales@*****.co.uk"
objMail.To = c
objMail.Subject = "Your password"
objMail.HTMLBody = Mailbody
'objMail.TextBody = mailbody
'objMail.MailFormat=0
'objMail.BodyFormat=0
objMail.Send
Set objMail = Nothing
end function
%>
<html>
<head>
<title>Forgotten Password</title>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link rel="stylesheet" href="Styles.css">
</head>
<body bgcolor="#FFFFFF">

<div id="content">
<div id="breadCrumb">
</div>
<h2 id="pageName">Forgotten Password </h2>
<div class="story">
<h3>
<%if Request("success") = "" then%>
</h3>
<form name="form1" method="post" action="forgotten_password.asp">
<table width="100%" border="0" align="center" cellpadding="5" cellspacing="1" class="story">
<tr>
<td colspan="2" class="detail" >
Please enter your email address.</td>
</tr>
<tr>
<td colspan="2" > </td>
</tr>
<%if Request("failed") <> "" then%>
<tr>
<td height="24" colspan="2" align="center" >Your
Email address is not in our database.</td>
</tr>
<%end if%>
<tr>
<td width="30%" height="29" align="right"> <strong>Your
Email Address:</strong></td>
<td width="70%" >
<input name="Email" type="text" class="search-box" id="Email3" size="35">
</td>
</tr>
<tr>
<td width="30%" height="6" align="center"> </td>
<td v height="6" width="70%"><input type="submit" name="Submit" value="Submit">
</td>
</tr>
</table>
<input type="hidden" name="Selected" value="1">
</form>
<%else%>
<br>
<br>
<table width="100%" border="0" align="center" cellpadding="0" cellspacing="0">
<tr>
<td width="100%">Thank you. Your password has been emailed
to you.</td>
</tr>
</table>
<%end if%>
</div>
<p>

</p>
</div>

</body>
</html>
<%
UsersRS.Close()
Set UsersRS = Nothing
%>

Thanks in adavnce

David

mat41 · October 18th, 2009, 06:10 PM

Next time you post point out the offending line. help others help you!!

'SendEmail' does expect a parameter which looks like an email address. I assume the error is here?

UserPassword=UsersRS("CustomerPassword")
SendEmail (THIS LINE)
Response.Redirect "forgotten_password.asp?success=true"
else

if so try chnaging this line to SendEmail([email protected])

futurehype · October 18th, 2009, 06:49 PM

Sorry about not highlighting. I didn't think.

But thanks for the quick reply. If I add an email address after SendEmail function the form, I'm guessing will only go to the address that I have placed in the code. The aim of the form is for the user to type in their email address then this page will pick their password from the database and send it to them. Is there a variable that I am missing which I have misplaced?

Thanks again

David

mat41 · October 18th, 2009, 07:06 PM

mmmmmm I will ask it another way:

Wrong number of arguments or invalid property assignment: 'SendEmail'

/forgotten_password.asp, line 27

Where is line 27

futurehype · October 18th, 2009, 07:52 PM

hi this is line 27

SendEmail

thanks again
david

mat41 · October 18th, 2009, 08:01 PM

;;; If I add an email address after SendEmail function the form, I'm guessing will only go to the address that I have placed in the code.

An email will go to the address you pass into the function yes (providing the function is free of bugs)

;;;Is there a variable that I am missing which I have misplaced?
No but you, as I have said, are trying to call a function which expects a value to be passed to it. If you want this value to be the emai address you need to change this line to:

SendEmail(UserEmail)

Provided that is a vaid email address and providing there are no other code errors it should work. it will solve your current error.

futurehype · October 19th, 2009, 07:39 PM

Thanks for the help. I've got it sorted now.