Create generic XSL Template to create table

Venkatachalapathy · #1 (**permalink**) March 10th, 2008, 01:03 PM

Hi,

I want a construct a dynamic table using XSLT template, I want the template to be generic. I want to pass column headers and the child nodes from which the column values to be selected. I'm able to pass the repeating element (e.g.) <People> dynamically and loop through the same, but I'm not able to pass nodes name and Title dynamically, I have to hardcode them in template....if I can pass this as generic, then I can use this template for any 2-columned table.

I'm using <xsl:with-param> to pass the repeating element, but when I use the same for child nodes also, it is not going to the appropriate child node of the parent context node.

Can you please help me with this one.

Requirement: One template should help me convert both the XML's, into a table.

<?xml version"1.0"?>
<Employees>
    <People>
        <Name> ABC </Name><Title> Analyst</Title>
    </People>
    <People><Name> GHI </Name><Title> Manager </Title>
    </People>
</Employees>

or
<TopExecutives>
     <Executive>
         <Name> XYZ </Name><Title> CEO </Title>
     </Executive>
     <Executive>
         <Name> MNO </Name><Title> CFO </Title>
     </Executive>
</TopExecutives>

Martin Honnen · #2 (**permalink**) March 10th, 2008, 01:07 PM

Do you want to transform XML to XML or XML to HTML? Can you show us the result you want the stylesheet to produce from your two XML samples?

Venkatachalapathy · #3 (**permalink**) March 10th, 2008, 01:14 PM

I want the output to be XSL-FO table.....you can visualize it as HTML table...

If XML-1 is passed, the output from XSL should be:
Name Title
ABC Analyst
DEF Manager

If XML-2, the output from XSL should be:
Name Title
XYZ CEO
MNO CFO

Martin Honnen · #4 (**permalink**) March 10th, 2008, 01:23 PM

Unfortunately I don't know XSL-FO (tables) but I will provide a stylesheet that creates a HTML table, solely based on the element level, the root element is transformed to the table element, the children of the root element are transformed to table rows and the grandchildren to table cells:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output method="html" indent="yes"/>

  <xsl:template match="/*">
    <table>
      <thead>
        <tr>
          <xsl:apply-templates select="*[1]/*" mode="th"/>
        </tr>
      </thead>
      <tbody>
        <xsl:apply-templates select="*"/>
      </tbody>
    </table>
  </xsl:template>

  <xsl:template match="/*/*/*" mode="th">
    <th>
      <xsl:value-of select="name()"/>
    </th>
  </xsl:template>

  <xsl:template match="/*/*">
    <tr>
      <xsl:apply-templates select="*"/>
    </tr>
  </xsl:template>

  <xsl:template match="/*/*/*">
    <td>
      <xsl:value-of select="."/>
    </td>
  </xsl:template>

</xsl:stylesheet>

Venkatachalapathy · #5 (**permalink**) March 10th, 2008, 01:45 PM

Thanks Martin !!!

It was a very quickly reply and provided a insight into processing the nodes in a different manner..

But I have more nodes in my XML repeating element, I want to pick only 2 nodes and use it for my table....HTML conversion should be fine, I can map it to XSL-FO....

<?xml version"1.0"?>
<Employees>
    <People>
        <Name> ABC </Name>
        <Title> Analyst</Title>
        <Salary> $12k </Salary>
        <Experience> 2 </Experience>
        <Project> DN123 </Project>
    </People>
    <People>
        <Name> GHI </Name>
        <Title> Manager </Title>
        <Salary> $15k </Salary>
        <Experience> 7 </Experience>
        <Project> DN123 </Project>
    </People>
</Employees>

or
<TopExecutives>
     <Executive>
         <Name> XYZ </Name>
         <Title> CEO </Title>
        <IsInBoard> Yes </IsInBoard>
        <BonusShares> 1200 </BonusShares>
     </Executive>
     <Executive>
         <Name> MNO </Name>
         <Title> CFO </Title>
        <IsInBoard> No </IsInBoard>
        <BonusShares> 500 </BonusShares>
     </Executive>
</TopExecutives>

Martin Honnen · #6 (**permalink**) March 11th, 2008, 07:49 AM

Well any algorithm creating the table needs to have some way to identify the elements you want to output. Assuming you want to output the first two elements here is a sample stylesheet:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output method="html" indent="yes"/>

  <xsl:template match="/*">
    <table>
      <thead>
        <tr>
          <xsl:apply-templates select="*[1]/*[position() &lt; 3]" mode="th"/>
        </tr>
      </thead>
      <tbody>
        <xsl:apply-templates select="*"/>
      </tbody>
    </table>
  </xsl:template>

  <xsl:template match="/*/*/*" mode="th">
    <th>
      <xsl:value-of select="name()"/>
    </th>
  </xsl:template>

  <xsl:template match="/*/*">
    <tr>
      <xsl:apply-templates select="*[position() &lt; 3]"/>
    </tr>
  </xsl:template>

  <xsl:template match="/*/*/*">
    <td>
      <xsl:value-of select="."/>
    </td>
  </xsl:template>

</xsl:stylesheet>

Need to download code?

Navigation