Title Case a string

bonekrusher · September 16th, 2010, 08:56 AM

Hi, I have a template that takes a string and makes it title case. for example:

"the man and the moon (MATM)"

will display:

"The Man And The Moon (Matm)"

I need to be able to ignore contractions (and, or) and acronyms (MATM)

I would like the output to be:

"The Man and The Moon (MATM)"

Here is my current template:

Code:

<xsl:template name="titlecase">
    <xsl:param name="text" as="xs:string"/>
    <xsl:sequence select="string-join(for $x in tokenize($text,'\s') return concat(upper-case(substring($x, 1, 1)), lower-case(substring($x, 2))), ' ')"/>
</xsl:template>

I am not sure whats the best approach.

Thanks for the help.

samjudson · September 16th, 2010, 09:15 AM

The easiest way would be to define a function and pass each string in to that. Then see if the string matches either one of your contractions, or is already all uppercase, and if so return unchanged.

Code:

   <xsl:function name="my:titleCase" as="xs:string">
		    <xsl:param name="s" as="xs:string"/>
		    <xsl:choose>
		       <xsl:when test="lower-case($s)=('and','or')">
				        <xsl:value-of select="lower-case($s)"/>
			      </xsl:when>
			      <xsl:when test="$s=upper-case($s)">
				        <xsl:value-of select="$s"/>
								</xsl:when>
				     <xsl:otherwise>
					       <xsl:value-of select="concat(upper-case(substring($s, 1, 1)), lower-case(substring($s, 2)))"/>
					    </xsl:otherwise>
							</xsl:choose>

	  </xsl:function>

Then use it like so:

Code:

<xsl:sequence select="string-join(for $x in tokenize($text,'\s') return my:titleCase($x),' ')"/>

Martin Honnen · September 16th, 2010, 09:19 AM

I tried it with analyze-string:

Code:

  <xsl:function name="mf:titlecase" as="xs:string">
    <xsl:param name="text" as="xs:string"/>
    <xsl:param name="ignore-list" as="xs:string*"/>
    <xsl:value-of>
      <xsl:analyze-string select="$text" regex="\w+">
        <xsl:matching-substring>
          <xsl:analyze-string select="." regex="{string-join($ignore-list, '|')}">
            <xsl:matching-substring>
              <xsl:value-of select="."/>
            </xsl:matching-substring>
            <xsl:non-matching-substring>
              <xsl:sequence select="concat(upper-case(substring(., 1, 1)), lower-case(substring(., 2)))"/>
            </xsl:non-matching-substring>
          </xsl:analyze-string>
        </xsl:matching-substring>
        <xsl:non-matching-substring>
          <xsl:value-of select="."/>
        </xsl:non-matching-substring>
      </xsl:analyze-string>
    </xsl:value-of>
  </xsl:function>

  <!-- call like this -->

  <xsl:value-of select="mf:titlecase($sentence, ('and', 'or', 'MATM'))"/>

bonekrusher · September 16th, 2010, 10:04 AM

Sam/Martin

Thanks for the quick reply!

Both solutions worked.

Thanks again

Regards,