I want to be able to open a txt file by clicking on a button on a form. This should display the Open File dialogue box.

This is quite simple in Excel, as it's just Application.GetOpenFilename but not the case in Acess 2000.

Some of the information we wish to store in a database is obtainable from text files, so it makes sense to scan through the text file for certain rows of information.

Thanks in Advance

You want the user to browse for the file? Or do you want to open the file on NotePad? How would this work?


mmcdonal

Locate the file, return the filename and path and then open the file for input to locate the required data and copy it into defined fields.
I have achieved all this, but have used a crude input box to ask for a filename in one location only.

use Microsoft Common Dialog Control ActiveX, or search web for implementation of functions of comdlg32.dll for VB.
Try www.pscode.com/vb, or www.freevbcode.com

Peko

There are bunch of API calls into the comdlg32 library floating around out there, but this is the leanest (fewest lines of code) I've ever come across. Clicking cmdGetFilePath opens the dialog and the selected path and file name are written to txtFilePath.

Private Type GetFilePath
  lStructSize As Long
  hwndOwner As Long
  hInstance As Long
  lpstrFilter As String
  lpstrCustomFilter As String
  nMaxCustFilter As Long
  nFilterIndex As Long
  lpstrFile As String
  nMaxFile As Long
  lpstrFileTitle As String
  nMaxFileTitle As Long
  lpstrInitialDir As String
  lpstrTitle As String
  flags As Long
  nFileOffset As Integer
  nFileExtension As Integer
  lpstrDefExt As String
  lCustData As Long
  lpfnHook As Long
  lpTemplateName As String
End Type

Private Declare Function GetFileName Lib "comdlg32.dll" Alias _
"GetOpenFileNameA" (pOpenfilename As GetFilePath) As Long

Private Sub cmdGetFilePath_Click()

    Dim filePath As GetFilePath
    filePath.lStructSize = Len(filePath)
    filePath.hwndOwner = Me.Hwnd
    filePath.lpstrFilter = "All File Types" + Chr$(0) + "*.*"
    filePath.lpstrFile = Space$(254)
    filePath.nMaxFile = 255
    filePath.lpstrFileTitle = Space$(254)
    filePath.nMaxFileTitle = 255
    filePath.lpstrInitialDir = "D:\My Data"
    filePath.lpstrTitle = "File Copy"
    filePath.flags = 0

    Dim strFilePath

    strFilePath = GetFileName(filePath)

    If (strFilePath) Then
        Me.txtFilePath.Value = Trim$(filePath.lpstrFile)
    Else
        Exit Sub
    End If

End Sub

Bob