How can I copy the contents of an A97 text box to the Windows clipboard please? I tried the following but it doesn't work:

  Text0.SetFocus
  SendKeys "^C"

Clive Astley

__________________
Clive Astley

Hi Clive,

In form module...

Private Sub CopyToClipboard_Click()
    Call ClipBoard_SetData(Me!fText)
End Sub


...Windows API calls in standard module...

Option Compare Database
Option Explicit

      Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) _
         As Long
      Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) _
         As Long
      Declare Function GlobalAlloc Lib "kernel32" (ByVal wFlags As Long, _
         ByVal dwBytes As Long) As Long
      Declare Function CloseClipboard Lib "User32" () As Long
      Declare Function OpenClipboard Lib "User32" (ByVal hwnd As Long) _
         As Long
      Declare Function EmptyClipboard Lib "User32" () As Long
      Declare Function lstrcpy Lib "kernel32" (ByVal lpString1 As Any, _
         ByVal lpString2 As Any) As Long
      Declare Function SetClipboardData Lib "User32" (ByVal wFormat _
         As Long, ByVal hMem As Long) As Long

      Public Const GHND = &H42
      Public Const CF_TEXT = 1
      Public Const MAXSIZE = 4096

      Function ClipBoard_SetData(MyString As String)
         Dim hGlobalMemory As Long, lpGlobalMemory As Long
         Dim hClipMemory As Long, X As Long

         ' Allocate movable global memory.
         '-------------------------------------------
         hGlobalMemory = GlobalAlloc(GHND, Len(MyString) + 1)

         ' Lock the block to get a far pointer
         ' to this memory.
         lpGlobalMemory = GlobalLock(hGlobalMemory)

         ' Copy the string to this global memory.
         lpGlobalMemory = lstrcpy(lpGlobalMemory, MyString)

         ' Unlock the memory.
         If GlobalUnlock(hGlobalMemory) <> 0 Then
            MsgBox "Could not unlock memory location. Copy aborted."
            GoTo ExitHere
         End If

         ' Open the Clipboard to copy data to.
         If OpenClipboard(0&) = 0 Then
            MsgBox "Could not open the Clipboard. Copy aborted."
            Exit Function
         End If

         ' Clear the Clipboard.
         X = EmptyClipboard()

         ' Copy the data to the Clipboard.
         hClipMemory = SetClipboardData(CF_TEXT, hGlobalMemory)

ExitHere:

         If CloseClipboard() = 0 Then
            MsgBox "Could not close Clipboard."
         End If

         End Function

HTH,

Bob

Many thanks Bob. Works perfectly.

Clive Astley

You're welcome Clive. Glad it got it for you.

Bob

Hi Bob:

I have been trying to write codes using API calls similar to the example you just gave but I have no clue where to start learning about these procedures. All the text books I have seen do not cover these topics.

Can you suggest how to get started (text books, on line tutorial etc). I am quite advanced in VBA but not in writing API calls so I will be starting form the basics.

Thanks

Hi stoneman,

As a general rule of thumb, I would never set about trying to write my own API call; I simply collect API calls that are known to work, and generally cut and paste them with few, if any, modifications. When you're calling external API functions you are no longer working in VBA's wonderfully safe environment. One simple typo can cause you to GPF (general protection fault), crash your app, and waste contless development hours trying to figure out what's up. Instead, find code that already has a good wrapper function around the API call you need, and tuck it away in a code library somewhere for future reference.

That said, there are some interesting resources out there...

The dlls that form the Windows API are not wrapped in type libraries, so you can't reference them in an Access app, and hence can't view their function definitions via the Object Browser. The obvious question then, is how do you know what the available API functions are?

Both the MS Office Developer Edition (ODE) and VB6 include a text file called WIN32API.TXT that contains VBA Declare statements for most of the functions in the Windows API (since VBA can't reference the relevant dlls [Kernel32.dll, User32.dll, Comdlg32.dll, etc.], the Declare statements are what tell VBA where to find a particular DLL function and how to call it). If you don't own either the ODE or VB6, you can download WIN32API.TXT for free from MS @:

http://www.microsoft.com/downloads/d...displaylang=en (watch word wrap)

In additioin to WIN32API.TXT, the ODE and VB6 come with a utility exe called the API Viewer. APILOAD.exe is a VB6 add-in but works fine as a stand-alone exe. See:

http://msdn.microsoft.com/library/de...pplication.asp

(look under the "Accessing the Microsoft Windows API" node in the MSDN treeview for a screen capture of the API Viewer).

The API Viewer allows you to load WIN32API.TXT into a fairly klunky GUI, write the Declares, Constants, and User-defined type definiftions you need to a Textbox, then paste the completed API call into your app. It also lets you convert WIN32API.TXT into an Access database. Frankly, I find it easier to simply open WIN32API.TXT in Notepad/Wordpad and search for a function I'm interested in.

Then once you locate the Declare you want, you need to know what it means, and what parameters it requires!! For that, you need one or all of the below:

- Somebody elses (hopefully commented) code [recommended]
- WIN32 documentation (the MSDN library CD's contain the MS Platform SDK and are the best source)
- several good books.

Some of the better Access books have good chapters on API functions:

Getz, et al - Access 2002 Developer's Handbook, Desktop Edition
F. Scott Barker - Microsoft Access 2002 Power Programming

There are also some good books on the Winows API geared toward VB developer's, but the VB Declares and wrapper functions are identical in VBA. The best in terms of an exhaustive reference is:

Dan Appleman's Visual Basic Programmer's Guide to the Win32 API

I've also worked with:

Visual Basic 6 Win32 API Tutorial - Jason Brock (Wrox)
Win32 API Programming with Visual Basic - Steven Roman (O'reilly)

HTH,

Bob