Hi there,
 I posted this thread few days ago, still couldn't solve it, if anyone can give me some suggestions, I will appreciate it!

 I use a dialog "menu" to collect search criteria.

 The "menu" dialog includes:
 client(combo box)
 Open_order(check box)
 submit(button)
 Private Sub submit_Click()
   DoCmd.OpenForm "order"
 End Sub
  (I am wondering how can I set criteria here and parse it to the "order" form)

 After the user click "submit" button in the "menu", a form named "order" should display all records which satisfy with the criteria.

 In the "order" form, I had a query

 My questions are as follows:
 If user doesn't select anything from the combo box(I should see all the clients in the "order" form).
  If the open_order isn't checked, I would see all the open orders in the "order" form.
  I don't know how can I set these criteria correctly in the query under the "order" form?



flyfish

flyfish

__________________
flyfish

Hi Flyfish,

You could create an unbound form and supply its recordsource at run time with a routine like this -

Private Sub cmdSubmit_Click()
Dim strSQL As String
Dim frm As Form

    'Build the basic Recordset
    strSQL = "SELECT tbl_Orders.Order_ID, tbl_Orders.Order, " & _
        "tbl_Orders.Customer_ID, tbl_Orders.Order_Open " & _
        "FROM tbl_Orders"

    'If either criteria is supplied then add a where clause
    If cboCustomer <> 0 Or chkOpen Then
        strSQL = strSQL & " WHERE ("

        'Now build the where clause using the criteria selected
        If cboCustomer <> 0 Then strSQL = strSQL _
                & "((tbl_Orders.Customer_ID)=" & cboCustomer & ") AND"

        If chkOpen Then strSQL = strSQL & _
            "((tbl_Orders.Order_Open)=" & chkOpen & ") AND"

        'Now remove the last and
        strSQL = Left(strSQL, Len(strSQL) - 4)

        'And apply the closing bracket
        strSQL = strSQL & ");"

    Else
        'Just append the closing ;
        strSQL = strSQL & ";"
    End If

    'Open the Orders form and set its recordsource property to the SQL we created
    DoCmd.OpenForm "Frm_Order"
    Forms![frm_Order].Form.RecordSource = strSQL

End Sub

The controls on your order form should be bound to the fields in your basic recordset. The FORMS recordsource remains unbound though. Let us know if this works for you.

HTH

Jp