Hi All
I have set up a user name and password for users to logon to a database. How do I prevent the user's from entering the database by holding the shift and open keys on the keyboard and letting me have access to the database in design view.

Thanks

Brendan Bartley

__________________
Brendan Bartley

Brendan,

Check the example here:

http://www.members.shaw.ca/AlbertKa...s/msaccess.html

But also you can probably do this:
**Just make sure that you there are quotes around 'AllowBypassKey' like this: ChangePropertyDdl ("AllowBypassKey", DB_Boolean, False).**


Function ChangePropertyDdl(stPropName As String, _
PropType As DAO.DataTypeEnum, vPropVal As Variant) _
As Boolean
' Uses the DDL argument to create a property
' that only Admins can change.
'
' Current CreateProperty listing in Access help
' is flawed in that anyone who can open the db
' can reset properties, such as AllowBypassKey
'
On Error GoTo ChangePropertyDdl_Err


Dim db As DAO.Database
Dim prp As DAO.Property


Const conPropNotFoundError = 3270


Set db = CurrentDb
' Assuming the current property was created without
' using the DDL argument. Delete it so we can
' recreate it properly
db.Properties.Delete stPropName
Set prp = db.CreateProperty(stPropName, _
PropType, vPropVal, True)
db.Properties.Append prp


' If we made it this far, it worked!
ChangePropertyDdl = True


ChangePropertyDdl_Exit:
Set prp = Nothing
Set db = Nothing
Exit Function


ChangePropertyDdl_Err:
If Err.Number = conPropNotFoundError Then
' We can ignore when the prop does not exist
Resume Next
End If
Resume ChangePropertyDdl_Exit
End Function