I cant seem to find the code to set the priority of the message High. Ive looked every were, using win2k code is below. I cant seem to find the schema anywhere.

In some cases this code is sent from the smtp on the webserver in some cases it goes to a remote exchange server using CDOBasic. In neither case have I been able to elevate the importance.

'on error resume next
Set Mssg = Server.CreateObject("CDO.Message")
set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields
    With Flds
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "MyWebServer"
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 10
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate")=0
        .Item("urn:schemas:httpmail:importance").Value = 2
        .Update
    End With

    with Mssg
    Set .Configuration = iConf
        .CreateMHTMLBody ("http://www.SomeWebsite.com/")
        .Subject = "Test Of Web Mail"
        .From = "[email protected]"
        .To = "[email protected]"
        .Send
    End With

Set Mssg=Nothing
Set iConf=Nothing
Set Flds=Nothing

OK I got it. What you have there is correct. But we need to add a few more things. You can get all this info from the following sources:

http://msdn.microsoft.com/library/de...figuration.asp

http://msdn.microsoft.com/library/de...alues_enum.asp

http://msdn.microsoft.com/library/de...es_message.asp

So what we have is this:

With iMsg
   Set .Configuration = iConf
   .To = strTo
   .From = strFrom
   .ReplyTo = strFrom
   .Subject = strSubject ' "This is a test CDOSYS message (Sent via Pickup)"
   .HTMLBody = strHTML
   Set Flds = .Fields
   With Flds
      If lngImportance = 0 Then
         .Item("urn:schemas:mailheader:X-Priority") = 5
      ElseIf lngImportance = 1 Then
         .Item("urn:schemas:mailheader:X-Priority") = 3
      Else
         .Item("urn:schemas:mailheader:X-Priority") = 0
      End If
      .Item("urn:schemas:httpmail:importance") = lngImportance
      .Item("urn:schemas:mailheader:X-MSMail-Priority") = lngImportance
      .Update
   End With
   '.Fields("urn:schemas:httpmail:importance").Value = lngImportance
   '.Fields.Update
   'TODO: if adding an attachment,
   'uncomment the next line and alter file path as required
   'Set iBP = iMsg.AddAttachment(App.Path & "\file1.txt")
   .Send
End With

Now note if the message is received in Hotmail you will not see the Impotance flag. You haver to open the message or save to your drive. If you open the message it will have the priority you expect.

Any issues let me know.

Thanks hesterloli.