This site worked on Windows 2000, but after I moved it to W2K3, I get this error whenever I have a Server.CreateObject command. This is the error:

Server object error 'ASP 0177 : 800401f3'

Server.CreateObject Failed

/contact/default.asp, line 15

800401f3


Here is part of my code:

<%sHeading = "Contact Us"%>
<%sTitle = "Company name: Contact Us"%>



<%
if Request("submitted") = 1 then
  BodyText = "<b>Name:</b> " & Request("name") & "<br>" &_
            "<b>Email Address:</b> " & Request("email") & "<br>" &_
            "<b>Phone Number:</b> " & Request("phone") & "<br>" &_
            "<b>Address:</b> " & Request("address") & "<br>" &_
            "<b>Company:</b> " & Request("Company") & "<br>" &_
            "<b>Comment:</b><br> " & Request("comment") & "<br>"

  Set oMailMessage = Server.CreateObject("CDO.NewMail")
    oMailMessage.from = "SignUp@Company name.net"
    oMailMessage.to = "SignUp@Company name.net, apps@Company name.net"
    oMailMessage.subject = "Contact Agent: Contact Requested"
    oMailMessage.MailFormat = 0
    oMailMessage.BodyFormat = 0 ' HTML
    oMailMessage.body = BodyText
    oMailMessage.Send()
%>

I have spend days searching the MS KB and Google to no avail.

I have seen a lot of similar issues but no one ever had a solution.

CDONTS is no longer part of W2K3.

You'll need to migrate to CDOSYS.

Bruce Luckcuck
Director, Applications & Support Services
Wiley Publishing, Inc.

So I need to change

Set oMailMessage = Server.CreateObject("CDO.NewMail")

to

Set oMailMessage = Server.CreateObject("CDOSYS.NewMail") ?

Well, I changed all applicable entries to CDOSYS and still had the same error.

Any other ideas? I'm getting kind of desperate.

CDOSYS is a different animal then CDONTS - you have to migrate your code to it, not just substitue the text. It's not hard though.

See that search box in the upper right-hand corner of the page. Type CDOSYS in there and click GO. You'll find a number of topics that will help.

Here's one to get you started.

Also, Google is your friend.

Bruce Luckcuck
Director, Applications & Support Services
Wiley Publishing, Inc.

After a lot of reading of the materials you listed, I found the solution. I made the change and it works with only one slight problem. I have three identical web sites on this server and I made the change to all of them. When I execute the code, 2 of them send mail from their own SMTP server on the web site to their own Exchange server; one of them sends the e-mail to the DROP folder. I've been unable to figure out why. I've deleted and recreated the SMTP Virtual server with no change.

Here's my new code:

<%sHeading = "Contact Us"%>
<%sTitle = "Company Name: Contact Us"%>



<%
'Create the e-mail server object
if Request("submitted") = 1 then
  BodyText = "<b>Name:</b> " & Request("name") & "<br>" &_
            "<b>Email Address:</b> " & Request("email") & "<br>" &_
            "<b>Phone Number:</b> " & Request("phone") & "<br>" &_
            "<b>Address:</b> " & Request("address") & "<br>" &_
            "<b>Company:</b> " & Request("Company") & "<br>" &_
            "<b>Comment:</b><br> " & Request("comment") & "<br>"

Set objCDOSYSMail = Server.CreateObject("CDO.Message")
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")
'Out going SMTP server
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "192.168.1.178"
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
objCDOSYSCon.Fields.Update

'Update the CDOSYS Configuration
Set objCDOSYSMail.Configuration = objCDOSYSCon
objCDOSYSMail.From = "SignUp@Company Name.net"
objCDOSYSMail.To = "SignUp@Company Name.net"
objCDOSYSMail.Subject = "Contact Agent: Contact Requested"
objCDOSYSMail.HTMLBody = BodyText
objCDOSYSMail.Send
'Close the server mail object
Set objCDOSYSMail = Nothing
Set objCDOSYSCon = Nothing