Looping through an HTML select box

tsparker · October 13th, 2003, 10:27 PM

I'm trying to loop through an HTML Select box, and iterate through each selection chosen.

Each selection is separate by a comma, and I'm trying to break each into it's own line...the code below works if I don't use the Do While.

Each selection is 4 characters long, plus a comma. So for example, this is what it would look like: 1234, 2345, 6789. But I'm trying to get it to look like this:
1234
5678
6789

Thanks for any help!

The Code:

    Do While len(strProducts) >= 4

    commaPos = InStr(strProducts, ",")

    If commaPos = 0 Then
        value = strProducts
        strProducts = " "
    Else
        value = Mid(strProducts, commaPos-4, 4)

        strProducts = Mid(strProducts, commaPos+2, Len(strProducts)-6)

        Response.Write value & "<br>"
        Response.Write strProducts & "<br>"

    End If
    Loop

balakumar1000 · October 14th, 2003, 12:03 AM

Why don't u use the methods of Select Element to get the selected values.

Balakumar V.

Imar · October 14th, 2003, 02:00 AM

Hi there,

It may be a lot easier to use the Split method. This method splits the Request.Form value (or any other string) based on a comma (or any other separator) and returns an array of the items in the string

You can then simply loop through the array, displaying each selected item. The following code shows you how this works:

Code:

<body>
<%
    If Request.Form("btnSubmit") <> "" Then
        Dim arrSelection
        Dim iLoop
        Dim iUBound
        arrSelection = Split(Request.Form("lstTest"), ",")
        iUBound = UBound(arrSelection) ' The last item in the array
            ' with a zero based index, so an UBound of 2 means 3 items
        For iLoop = 0 to iUBound
            Response.Write("Selected Item " & arrSelection(iLoop) & "<br />")
        Next
    End If
%>
<form id="frmTest" name="frmtest" method="post" action="test.asp">
    <select name="lstTest" multiple="multiple" size="5">
        <option value="1234">1</option>
        <option value="2345">2</option>
        <option value="3456">3</option>
        <option value="4567">4</option>
        <option value="5678">5</option>
    </select>
    <input type="submit" name="btnSubmit" value="submit">
</form>
</body>

Hope this helps,

Imar

---------------------------------------
Imar Spaanjaars
Everyone is unique, except for me.

tsparker · October 15th, 2003, 01:18 AM

Thanks Imar...works, and it is a lot easier to do...

t~