Could someone help on this?
I am working in A2K, and have an .MDB that I am using to launch a Word Doc with mail merge fields already made. I am using the example in Access 2003 VBA pg. 462 as my guide.

My code bombs at the opendatasource method. The error I'm getting is saying the "Server threw an error" (!!) and it references number -2147417851 (80010105). Word does launch to the correct document, so the filename property of the dialog box is at least populated. I want to merge the data, and in so doing, pass a WHERE clause into the SQL. I just can't get it to take my arguments for the opendatasource method. Does anyone know WHICH common dialog controls components to check? Am I missing an argument- perhaps they have changed between 2K and 2003? We've tested the path and it's correct. The Word Template launches, but I want to narrow the SQL programatically for the user.

Thanks,
Loralee

************ my code
Private Sub cmdOpenPCL_Click()
' this is an attempt to open a Word document and start a mail merge
Dim strFilePath As String
Dim objWord As Word.Document
Me.cmdlg.DialogTitle = "Choose File Name and Location"
Me.cmdlg.ShowOpen
strFilePath = Me.cmdlg.FileName


Set objWord = GetObject(strFilePath, "Word.document")
' make word visible
objWord.Application.Visible = True

objWord.MailMerge.OpenDataSource Name:="C:\Documents and Settings\My Name\My Documents\" & _
"CTU Provider Management 11022005 1726\", _
linktosource:=True, _
Connection:="TABLE tblPatient", _
sqlstatement:="SELECT * FROM tblPatient" ' bombs here with "server threw an error"

' execute the mail merge
objWord.MailMerge.Execute

End Sub

Did you ever figure this out? I'm having same problem with the opendatasource.

I never got it to work the way the book example showed. Another thread for this problem is:

http://p2p.wrox.com/topic.asp?TOPIC_ID=36365

(Other Forum members had some ideas that may work for you). Perhaps it has to do with my db being in A2K........ and the example was for Access 2003.

However, I used a work-around which gets me what I wanted. I've taken the PK from the form user is on, and set the WHERE of the query that will underly the Word DOT to be merged through the querydef collection.
For this to work the target WOrd documents MUST be .DOTs and they MUST be set up as mail merge documents with their OpenDataSource set to the target query.
THis has really saved us alot of time as well as allowed staff who can create WORD docs to create the templates and mail merge docs.
It also is easy for us to then customize letters that are otherwise form letters. (It was worth the sweat).


HTH,

Loralee

*****************************
Private Sub cmdMergeLetter_Click()
' this is an attempt to open a Word document and start a mail merge
Dim strFilePath As String
Dim objWord As Word.Document
Dim strPatientID As String ' use to link to PK of the form this launches from
Dim strSELECT As String
Dim strFROM As String
Dim strWHERE As String
Dim strSQLMerge As String

strPatientID = Forms!frmpatientdata.txtPatientID ' launch from this form
strSELECT = "SELECT tblPatient.[PatientID], tblPatient.[PtFirstName], tblPatient.[PtLastName], tblPatient.[PtBD], tblCity.[City], tblPatient.[PtAddress], tblPatient.[PtZip], tblReferral.[ReferBy]"
strFROM = " FROM (tblCity INNER JOIN tblPatient ON tblCity.[CityID] = tblPatient.[PtCityFK]) INNER JOIN tblReferral ON tblPatient.[PatientID] = tblReferral.[PtFK]"
strWHERE = " WHERE ((([PatientID])= " & strPatientID & "))"
strSQLMerge = strSELECT & strFROM & strWHERE

CurrentDb.QueryDefs("qrymailmerge").SQL = strSQLMerge

Me.cmdlg.DialogTitle = "Choose File Name and Location"
Me.cmdlg.ShowOpen
strFilePath = Me.cmdlg.FileName

Set objWord = GetObject(strFilePath, "Word.document")
' make word visible
objWord.Application.Visible = True

' execute the mail merge
objWord.MailMerge.Execute
objWord.Close

End Sub