Hi all,

Just a quick question - I think I am right but want to confirm.

One page 353 the book mentions how you can still call the original method if you specifically call it from within the new method (overriding the original) by using Base.MethodName etc.

I understand this for 2 objects, but lets say I had 3 objects, and they were something like this:

Object 1
--->Object 2 (inheriting from Object 1)
------->Object 3 (inheriting from Object 2)

Now, if I wanted to do what the book is talking about - does Base.Methodname refer to the object that this object inherits from - or rather the 'first' object in the series of objects.

Ie, all 3 objects above were to have the same method (each doing something slightly different) - and each one overrides the other, if in Object 3 I then called a method using Base.MethodName etc - would I be correct in saying that it would take the MethodName from Object2 and not Object1?

Sorry if I've overly complication my question by trying to explain it



Regards

Rob

__________________
Regards

Rob

Rob,

You are correct, Object3 would only call the base method in the class that it is inheriting (Object2). However, Object2 could in turn call the base method in the class that it is inheriting (Object1) and return the results from that method.

As a side note, the book had a typo and it should be MyBase.MethodName instead of Base.MethodName.

Here's an example:

Public Class Class1
    Overridable Function ReturnString() As String
        Return "From Class1"
    End Function
End Class

Public Class Class2
    Inherits Class1

    Overrides Function ReturnString() As String
        Return MyBase.ReturnString & ", From Class2"
    End Function
End Class

Public Class Class3
    Inherits Class2

    Overrides Function ReturnString() As String
        Return MyBase.ReturnString & ", From Class3"
    End Function
End Class

In a form add this code for a Button click event:

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim objTest As New Class3
        Debug.WriteLine(objTest.ReturnString)
    End Sub

The results that you'll see are:

From Class1, From Class2, From Class3

I hope this helps.

Thearon

Hello Thearon,

Many thanks for your prompt and informative reply, and for the heads up on the typo - I'm sure I'd have spotted that if I wasn't up so late reading the book! :)

Incidentally, can I take it that you are 'Thearon' from the book, ie the chappy on the left? Just curious as its always nice to put a face to a name etc.

Thanks again


Regards

Rob

Rob,

You're welcome and yes that's me.

Thearon

Nice to meet you - even if virtually :)


Regards

Rob