How do you use CDOSYS mail

SoC · April 17th, 2005, 08:14 PM

Hi,

Until recently I had been using CDONTS to allow people to send mail via a form.

We recently upgraded to IIS 6, Windows 2003 and my form no longer works. I understand that CDONTS is not included with Windows 2003.

I managed to find an example of CDOSYS on the MS KB site(http://msdn.microsoft.com/library/de...cdosys_vbs.asp).

I'm a total newbie though, and it doesn't make much sense.

Just wondering if someone can describe in fairly basic terms how to convert my CDONTS mail code to CDOSYS.

This is my code:

Code:

Request.Form("form1")

Dim fName, surname, comments, cb1, cb2

Dim theMail

fName = Request.Form("fName")
surname = Request.Form("surname")
comments = Request.Form("comments")
cb1 = Request.Form("cb1")
cb2 = Request.Form("cb2")

        Set theMail = Server.CreateObject("CDONTS.NewMail")

        theMail.From = "[email protected]"

        theMail.To = "[email protected]"

        theMail.Cc = "[email protected]"

        theMail.Bcc = ""

        theMail.Subject = "Form Submission"


theMail.Body = "Firstname; " & fName & "<br>" & _
        "Surname; " & surname & "<br>" & _
        "Position; " & position & "<br>" & _
        "Comments/Questions; " & comments & "<br>" & _
        "Checkbox1; " & cb1 & "<br>" & _
        "Checkbox2; " & cb2 & "<br>" 

theMail.BodyFormat = 0

        theMail.MailFormat = 0
        theMail.Send
        Set theMail = nothing
 %>

Thanks very much

S

mat41 · April 17th, 2005, 08:30 PM

Here is an overview including a working example:

http://www.webafrica.co.za/kb/sendin..._overview.html

;;;my form no longer works
Your form still works, you just dont have the CDONTS.dll You can make it work by downloading and registering this .dll

I believe CDONTS is considered old and is no longer present by default. If you have allot of pages to change, it would be easier making CDONTS work.

Wind is your friend
Matt

SoC · April 17th, 2005, 09:24 PM

Hi Matt,

I tried adapting the code from the link you siggested but I get the following error:
error '80040211'

I already got the IT guys to install CDONTS.dll, but then I got a permission error. I've let them know, and I think they should be able to fix it.

Given the Microsoft recommend using CDOSYS instead of CODONTS, I wanted to see if I could get it to work, but from searching around the web it seems lots of people have had issues with it. Seems like it's more trouble than it's worth.

Any more tips greatly appreciated,
Thanks
S

mat41 · April 17th, 2005, 09:36 PM

Yes I agree CDOSYS would be better. I have not used CDOSYS, its about time I did. I am working om something at the moment, when I have finished I will get CDOSYS working and send you the code - it will be shortly.

About the permission error, strange...
As I said before, I have allot of pages using CDONTS so I simply registered the .dll and it worked without a problem. It would seem they have registered it otherwise you would be getting an error when it references the library file. I will get back to you...

Wind is your friend
Matt

mat41 · April 19th, 2005, 10:33 PM

Sorry I got a bit busy. I have tested this on a 2003 server, the code is strait from the MS website. If this doesnt work for you its not the code, its your SMTP set up (or the lack of), firewall, etc..


<%
Const cdoSendUsingPort = 2
Dim iMsg,iConf,Flds,strHTML,strSmartHost
StrSmartHost = "your mail IP - is a string"
set iMsg = CreateObject("CDO.Message")
set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields

'set the CDOSYS configuration fields to use port 25 on the SMTP server
With Flds
.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = cdoSendUsingPort
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = strSmartHost
.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 10
.Update
End With

'apply the settings to the message
With iMsg
Set .Configuration = iConf
.To = "[email protected]"
.From = "[email protected]"
.Subject = "CDOSYS Test"
.HTMLBody = "sent using CDOSYS"
.Send
End With

' cleanup of variables
Set iMsg = Nothing
Set iConf = Nothing
Set Flds = Nothing
%>

BTW: I had no trouble getting this to work. In fact I have just tryed it on a server that was not happy sending external (outside our network) mail using CDONTS. This method works like a charm.

Wind is your friend
Matt

SoC · April 20th, 2005, 10:56 PM

Thanks for your help, Matt.

It turns out we haven't got SMTP server at the moment! I think the code should work once they get it set up.

cheers

s