Looking for an elegant solution

fizzerchris · February 1st, 2006, 07:36 PM

I have a working webpage, but I am thinking there's a more elegant solution than this "brute force" method.

I have a drop down <select> box that lists each month, and want it to have the current month selected automatically. I dim a variable and initialize it:
  curMonth = MonthName(Month(Date))

Then I have 12 of the following, one for each month:
  If curMonth="January" Then
    Response.Write "<OPTION VALUE='January' SELECTED='Selected'>January</OPTION>"
  Else
    Response.Write "<OPTION VALUE='January'>January</OPTION>"
  End If

Is there a more elegant solution than having one of these code chunks for each month?

ChrisScott · February 2nd, 2006, 05:15 AM

You could do something like this...

Code:

Dim curMonth
curMonth = Month(Date)
Dim monthArr
monthArr = Array("January", "February", "March", "April", "May", "June", _
                "July", "August", "September", "October", "November", "December")    
Dim i
For i = 0 To UBound(monthArr)
    Dim selected
    If i + 1 = curMonth Then
        selected = " selected=""selected"""
    Else
        selected = ""
    End If
    Response.Write "<option value=""" & monthArr(i) & """" & selected & ">" & monthArr(i) & "</option>"
Next

fizzerchris · February 2nd, 2006, 07:13 PM

Great, thanks for the direction... I got it to work with some modifications.

Dim curMonth
curMonth = MonthName(Month(Date))

Dim monthArr
Dim selected

monthArr = Array("January", "February", "March", "April", "May", "June", _
                "July", "August", "September", "October", "November", "December")
Dim i
For i = 0 To UBound(monthArr)
  If monthArr(i) = curMonth Then
    selected = "selected='selected'"
  Else
    selected = ""
  End If
  Response.Write "<option value='" & monthArr(i) & "' " & selected & ">" & monthArr(i) & "</option>"
Next

jigscalypso · February 2nd, 2006, 07:54 PM

how abt this ?

for i = 0 to 11
selected = ""
if (currMonth = i-1) selected = " selected "
response.write "<option value='" & MonthName(i) & "'" & selected & ">" & MonthName(i) & "</option>"
next i

thanks

jigs