who is online?

keyvanjan · #1 (**permalink**) May 14th, 2006, 04:25 AM

Hi,
I have designed a membership script.
it has also a last logon field which gets the date/time(now())
when user logs in.
now how can I write a code that shows which user is online at that time?
a user might login at 1 am but after a few hours this time remain in the db!

woodyz · #2 (**permalink**) May 14th, 2006, 09:38 AM

One way is to keep track of the users session.
In the global.asa file you can handle the event for Session_OnEnd. In that event handler you would place code that marks the users record in the database as being off-line, or to do whatever you need to change in your database (or whereever) that the user is no longer active in the systems.

Make sense?

Woody Z http://www.learntoprogramnow.com

keyvanjan · #3 (**permalink**) May 14th, 2006, 12:35 PM

I need a code sample!

keyvanjan · #4 (**permalink**) May 14th, 2006, 12:41 PM

Is there any way without global.asa
sth like this code StrOnlineTimedout = dateadd("n",-strtimeout*60,onlinedate)
that when a user logs on it shows him online until 1 hour(the period the session exipres)

woodyz · #5 (**permalink**) May 15th, 2006, 09:01 AM

Well... what exactly would StrOnlineTimedout be used to do?
Where is it declared - in which asp file? It is just a variable - what code is going to use it, and what will it do with it?
Why not use the global.asa? Perhaps I am misunderstanding you.

Woody Z http://www.learntoprogramnow.com

keyvanjan · #6 (**permalink**) May 23rd, 2006, 03:58 AM

woodyZ how can I place that code in global.asa
can you give an example?

woodyz · #7 (**permalink**) May 23rd, 2006, 10:00 AM

Here is a very simple example.

First, the global.asa

Code:

<SCRIPT LANGUAGE="VBScript" RUNAT="Server">

'This is a very simplistic  example.

Sub Application_OnStart
    ' Ths initializes the counter
    Application("ONLINE_COUNT") = 0
End Sub

Sub Session_OnStart
    ' Use whatever timeout you want.  This sets it to 1 minutes for test purposes
    ' so you can easily see the count go down as sessions are ended...
    Session.Timeout = 1

     ' By setting a session variable when we first start a session we make sure that
     '    a session is actually started.
     Session("STARTED") = Now    
     ' Increment that counter that keeps track of users with an active session
     Application.Lock
         Application("ONLINE_COUNT") = Application("ONLINE_COUNT") + 1
     Application.UnLock

End Sub

Sub Session_OnEnd
    ' Decrease the active visitors count when the session ends. 
    Application.Lock
        Application("ONLINE_COUNT") = Application("ONLINE_COUNT") - 1
    Application.UnLock
End Sub

</SCRIPT>

and now a simple page to demonstrate:

Code:

<%

' I named this page ShowCount.asp
function GetCount
    s = "The count is: " & Application("ONLINE_COUNT") & "<br/>"   
    GetCount = s
end function

function GetSessionStart
     GetSessionStart = "I signed on at: " & Session("STARTED") & "<br/>"
end function
%>


<html>
<head><title>Count Users Test</title></head>
<body>
     <%=GetCount %>
     <%=GetSessionStart %>     
</body>
</html>

I found an example of what you want here:
http://www.asp101.com/articles/john/...ve_users_2.asp

Woody Z http://www.learntoprogramnow.com

Need to download code?

Navigation