I have a real problem here. I'm trying to configure a web
server which is Server 2003 with IIS and SMTP installed.
When I run my asp pages, my CDONTS object return an error
on the page which is Microsoft VBScript runtime
error '800a0046'. Permission Denied.

Please help me to send this email.
Thanks so much to your help.
Regards.
Hoang Phuc

The CDONTS dll is not shipped with win 2003. You need to use CDOSYS. Did you ask Goggle? Typing in 'sending ASP mail from 2003 server' prpbably tells you in the first search result. The CDOSYS code is:
<%
Const cdoSendUsingPort = 2
Dim iMsg,iConf,Flds,strHTML,strSmartHost
StrSmartHost = "xxx.xx.xx"
set iMsg = CreateObject("CDO.Message")
set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields

With Flds
   .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = cdoSendUsingPort
   .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = strSmartHost
   .Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 10
   .Update
End With

With iMsg
   Set .Configuration = iConf
   .To = "[email protected]"
   .From = "[email protected]"
   .Subject = "Some subject"
   .HTMLBody = "Test message body"
   .Send
End With

Set iMsg = Nothing
Set iConf = Nothing
Set Flds = Nothing

%>

Wind is your friend
Matt