Parsing from a text string

jroxit · November 17th, 2008, 06:05 PM

I'm trying to do something that I have a feeling should be pretty simple. I need to pull out variables from a text string.

The string is:

client=1|invno=123|filter=yes|food=calamari

The variables themselves are dynamic. I'm trying to use the |(pipe) as a separator character.

Any ideas are truly appreciated.
:)

Old Pedant · November 17th, 2008, 06:17 PM

So do you mean that, in the end, you want to have VBScript variables with the same names set to those values??

There are several ways to do this, but as ugly as the following looks, it's probably the most efficient:

Code:

<%
...
str = "client=1|invno=123|filter=yes|food=calamari"

pairs = Split( str, "|" )
For p = 0 To UBound(pairs)
    vv = Split( pairs(p), "=" )
    vname = vv(0)
    vvalue = vv(1)

    ' could also check for boolean and datetime values and could special case integers
    If IsNumeric(vvalue) Then vvalue = CDbl(vvalue) 

    ' then assign to correct variable
    Select Case vname
        Case "client" : client = vvalue
        Case "invno"  : invno  = vvalue
        Case "filter" : filter = vvalue
        Case "food"   : food   = vvalue
        Case Else : Response.Write "Unrecognized variable name: " & vname & ""
    End Select
Next
...
%>

****************

Note that the code
filter = vvalue
will cause an error, because filter is a keyword. You can choose another variable name.

Old Pedant · November 17th, 2008, 08:22 PM

Just for the tasty flat fish*, here's another way:

Code:

<%
str = "client=1|invno=123|xfilter=yes|food=calamari"

Set re = New RegExp
re.Pattern = "\=([^\|]*)\|"
re.Global = True

Execute re.Replace( str & "|Rem", "=""$1"" : " )
%>

client: <%=client%><br>
invno: <%=invno%><br>
xfilter: <%=xfilter%><br>
food: <%=food%>

Has the disadvantage that all your variables will be string values (that is, will do
client="1"
instead of
client=1
) but...

I had to change your filter to another name; filter is a keyword in VBScript, so you can't assign to it.

**********************************

* halibut

jroxit · November 18th, 2008, 01:39 PM

Old...the 2nd example you showed would be great. How would I go about changing the text field to a numeric field after the fact? The xfilter field would need to be multiplied in a couple more programming lines.

Thanks!!!

jroxit · November 18th, 2008, 01:42 PM

What I'm actually trying to do is stack up a bunch of variables, send the whole string as a "pass-through" value on someone else's programming, then get it back and break it up again. *sigh* I'm only allowed one passthrough string. So, all the variable I listed would have a coordinating value already, I just need to send it to the next routine.

Thanks!

Old Pedant · November 18th, 2008, 05:08 PM

xfilter = CDBL(xfilter)

Presto, it's now a numeric value.

&&&&&&&&&&&&&&

I'm afraid I have no idea what you are really trying to do. I dunno what a "pass-through" string is, unless you mean a query string.

Oh! Wait! You must be talking about something like a payment processing system. So you mean the "pass-through" is (a) completely in your control and (b) it will be completely UNALTERED by the other system.

If that's so, then I recommend my first solution as superior. It has the huge advantage that you can, indeed, be sure you are getting the right value type (string, integer, double, etc.) on the final page. And it's also *much* faster and more efficient than the Execute scheme, which is really a CPU hog.