<%

Dim sDatabaseName
sDatabaseName = "C:\testDatabase.mdb"

' First call the Create Database method

CreateAccessDatabase sDatabaseName


' Then add a table and columns to this database
CreateAccessTable sDatabaseName


Sub CreateAccessDatabase(strDBPath)
        Dim catNewDB ' As ADOX.Catalog
        Set catNewDB = Server.CreateObject("ADOX.Catalog")
        catNewDB.Create "Provider=Microsoft.Jet.OLEDB.4.0;" & _
                "Data Source=" & strDBPath & _
                ";Jet OLEDB:Engine Type=5;"
                        ' Engine Type=5 = Access 2000 Database
                        ' Engine Type=4 = Access 97 Database
        Set catNewDB = Nothing
End Sub


Sub CreateAccessTable(strDBPath)
        Dim catDB ' As ADOX.Catalog
        Set catDB = Server.CreateObject("ADOX.Catalog")
        Dim tblNew  ' As ADOX.Table
        Set tblNew = Server.CreateObject("ADOX.Table")
        ' Open the catalog.
        catDB.ActiveConnection = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
                "Data Source=" & strDBPath
        ' First Create an Autonumber column, called ID. This is just for demonstration.
        ' I could have done this below with all the other columns as well
        Dim col ' As ADOX.Column
        Set col = Server.CreateObject("ADOX.Column")
        With col
                .ParentCatalog = catDB
                .Type = adInteger
                .Name = "ID"
                .Properties("Autoincrement") = True
        End With
        tblNew.Columns.Append col
        ' Now add the rest of the columns
        With tblNew
                .Name = "Contacts"
                ' Create fields and append them to the
                ' Columns collection of the new Table object.
                        With .Columns
                                .Append "aNumberColumn", adInteger
                                   .Append "FirstName", adVarWChar
                                   .Append "LastName", adVarWChar
                                   .Append "Phone", adVarWChar
                                   .Append "Notes", adLongVarWChar
                        End With
                        Dim adColNullable       
                        ' Is not defined in adovbs.inc, so we do it
                        '   by hand. 
                        ' The other option is:
                        ' adColFixed with a value of 1
                        adColNullable = 2
                        With .Columns("FirstName")
                                .Attributes = adColNullable
                        End With
        End With
        ' Add the new Table to the Tables collection of the database.
        catDB.Tables.Append tblNew
        Set Col = Nothing
        Set tblNew = Nothing
        Set catDB = Nothing
End Sub
%>