I posted this in an earlier topic, but it was in the wrong forumsection.


I am facing a similar problem, where I am **trying** to delete a node in the middle of similar nodes, eg trying to delete b(1) (with c2 value "Hello!"):


<?xml version="1.0"?>
<a>
 <b>
  <c1></c1>
  <c2></c2>
 </b>
 <b>
  <c1></c1>
  <c2>Hello!</c2>
 </b>
 <b>
  <c1></c1>
  <c2></c2>
 </b>
</a>



The code I have so far is:

Set o_xmlSettingsDocument=Server.CreateObject("Microso ft.XMLDOM")
o_xmlSettingsDocument.async=false
o_xmlSettingsDocument.load(Server.MapPath("system\ settings.xml"))

function f_DeleteXMLLink(v_intLink)
    dim v_strReturn
    dim o_xmlNode

    set o_xmlNode=Server.CreateObject("Microsoft.XMLDOM")

    set o_xmlNode=o_xmlSettingsDocument.getElementsByTagNa me("a/b[" & v_intLink & "]")

    Set o_xmlSettingsDocument = o_xmlNode.removechild(o_xmlSettingsNode.item(v_int Link))

    set o_xmlNode=nothing

    f_DeleteXMLLink=v_strReturn
end function



Like I said before, I _bet_ you don't know the answer.

Hi,

Here i've written a function for deleting a specific node from the xml file.
As you've asked, this function accepts a string as arguments (in your case it is the string "Hello"), the function searches
for the given string in a particular node (here it is node "c2"). if a matching node is found, it will be deleted from the
xml document and document gets saved.

the function will return true or false based on the operation done
here i've used XPATH queries to search the nodes in the xml document (one of the fastest way)
hope this function would help solve your problem


function deleteXMLNode(strText)
    Dim xmlDoc, xmlNode
    Dim bDeleted

    Set xmlDoc = Server.CreateObject("Microsoft.XMLDOM")

    xmlDoc.Load Server.MapPath("system\settings.xml")

    Set xmlNode = xmlDoc.selectSingleNode("a/b[c2='" & Trim(strText) & "']")

    If Not xmlNode Is Nothing Then
        xmlDoc.documentElement.removeChild xmlNode
        bDeleted = True
    Else
        bDeleted = False
    End If

    xmlDoc.Save Server.MapPath("system\settings.xml")

    deleteXMLNode = bDeleted
end function



Regards,
Raghu