I need to be implement a feature that sends a screen print of an Excel 2000 VBA form to the printer upon clicking on a button. I am using the 'PrintForm' feature i.e. frmMainForm.Printform

I have encountered the following problems:
1. Certain frame captions are not printing out
2. The form prints in portrait mode, therefore cutting off parts of the form.

Is there a way to make the form print in landscape mode and fix the problem with the captions? Ideally I would also like to be able to add a header and footer.

Regards

I went digging and found this code on another forum. I've tested it and it works to fix the problem of shrinking the form so that it fits on the printed page.

'=================
Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal _
  bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

Private Const KEYEVENTF_KEYUP = &H2
Private Const VK_SNAPSHOT = &H2C
Private Const VK_MENU = &H12

'================================================= ====================

Private Sub CommandButton1_Click()

Dim wb As Workbook
Dim sh As Worksheet

CommandButton1.SetFocus
AltPrintScreen
DoEvents

Application.ScreenUpdating = False

Set wb = Workbooks.Add(template:=xlWBATWorksheet)
Set sh = wb.Sheets(1)

sh.Paste

With sh.PageSetup
    .FitToPagesTall = 1
    .FitToPagesWide = 1
    .Orientation = xlPortrait
    .Zoom = False
End With

sh.PrintOut

wb.Close False

Application.ScreenUpdating = True

Set sh = Nothing
Set wb = Nothing

End Sub

'================================================= =========================

Private Sub AltPrintScreen()
    keybd_event VK_MENU, 0, 0, 0
    keybd_event VK_SNAPSHOT, 0, 0, 0
    keybd_event VK_SNAPSHOT, 0, KEYEVENTF_KEYUP, 0
    keybd_event VK_MENU, 0, KEYEVENTF_KEYUP, 0
End Sub

I discovered that you can call on WordBasic to solve the problem for you in Word:

WordBasic.SendKeys "{1068}"

This sends an image of the form to the clipboard.

From there, you can paste it from the clipboard manually into a document and print the page.

You can automate the document creation, pasting, and printing process, too, if you do not want to do it manually.

Of course, the best solution would be a patch for VBA's PrintForm function.