hi,
i want to get some info out of a excel document into Word.
I have found the next code on the internet:

Dim xlApp As Excel.Application
Dim xlWB As Excel.Workbook

Set xlApp = CreateObject("Excel.Application")
xlApp.Visible = True

Set xlWB = xlApp.Workbooks.Open("C:\Foldername\Filename.xls")
With xlWB.Worksheets(1)

end with
xlWB.Close False
xlApp.Quit

only when i run the procedure i get the next compile error:

user - defined type not defined

on the line : Dim xlWB As Excel.Workbook

how can i prevent this?

Just make a reference to 'Microsoft Excel xx.0 Object Library' from Tools-References in the VBA editor.

If you want to copy a range from Excel, try change your code a little:

Sub FromWord_CopyPasteExcelRange()
Dim xlApp As excel.Application
Dim xlWkBk As excel.Workbook
Dim xlWkSht As excel.Worksheet
Dim xlRng As excel.Range

Set xlApp = CreateObject("Excel.Application")
Set xlWkBk = xlApp.Workbooks.Open("j:\book2.xls")
Set xlWkSht = xlWkBk.Worksheets("Sheet1")

Set xlRng = xlWkSht.Range("A1:C3")
    xlRng.Copy
    ThisDocument.Activate
    Selection.PasteAndFormat (wdPasteDefault)

xlWkBk.Close False
xlApp.Quit

End Sub