I am getting this error -

Run time error '91':
Object variable or With block variable not set

and the code that has this error is -
i = Worksheets("Results").Columns(3).Find("Name").Row

the worksheet Results has the text "Name" in some row of column 3.
Do I need to define something... what am I missing ?

Thanks for helping.

I am not as familiar with the Find function, but I usually get this error if I have mispelled the Worksheet Name.

If that is not the case, I would maybe try something like.

Worksheets("Results").Select
ActiveSheet.Columns(3).Find("Name").Row

If that still doesn't work, look to see if you can break the second line into 2 lines, and then see which line the error occurs on to further narrow it down.

Hope that helps,

Mike

Mike
EchoVue.com

Use a range to get the result of the find

like

Set MyRange =Worksheets("Results").Columns(3).Find(what:="Name ")

If Not MyRange is nothing then
  i = MyRange.row
Else
  ' The text is not found
End if

Cheers
Shasur

http://www.vbadud.blogspot.com

What I have found when you get an error 91, is that the item that you are searching for is not there. I just error trap the code to either put to an error log file or I ignore that problem in the error trapping code.

The find routine is setting a range value to a variable. This requires proper syntax to work properly without returning an error. Note that I use Option Explicit so I define my variables first.

The proper use of Find routine:
-----------------------------------------------------------------------------------------
'Shows an example on how Find and FindNext work in Excel. Note that in the below example,
' FindNext uses the same range varible for both the solution and the 'seed' value so that
' the next time the same code is executed it would be the second found value being the starting
' point instead of the first found
Dim rFound As Range, iFirstRow As Long, iSecondRow As Long, sMessage As String
Set rFound = Worksheets("SheetName").Range("C:C").Find("Name", lookin:=xlValues) 'Finds first instance only
If Not rFound Is Nothing Then
  iFirstRow = rFound.Row
  Set rFound = Worksheets("SheetName").Range("C:C").FindNext(rFou nd) 'Finds next starting from last found
  If Not rFound Is Nothing Then iSecondRow = rFound.Row 'If no value is found, rFound would be Nothing.
End If
sMessage = "First Found: "
If iFirstRow > 0 Then sMessage = sMessage & iFirstRow Else sMessage = sMessage & "N/A"
sMessage = sMessage & vbCrLf & "Second Found: "
If iSecondRow > 0 Then sMessage = sMessage & iSecondRow Else sMessage = sMessage & "N/A"
MsgBox sMessage
-----------------------------------------------------------------------------------------

Hope this clears things up for you.