Here is my problem:

I want to check each cell in column A with every cell in column B and want to copy the cell to another text file if any cell value in column A does NOT exist in column B and vice versa. That might be a very simple code but since I know writing codes as much as writing in French :) this will take my days to figure it out alone.

I will appreciate any tips.

Thanks in advance.

To be more specific assume that my first column A includes:

William
Joe
Tom
John
Bill

and column B includes:

Bill
William
Amy
John
Tom
Henry


I want the code to find me Joe and copy&paste it somewhere (preferably in a text file or in another sheet lets say to A1 in sheet 2) and next find Amy (and then Henry) and copy paste in another sheet (to lets say A1 and A2 in sheet 3) or in a text file.

Joe must be found because it is in column A but not in column B.
Amy&Henry must be found because they are in column B but not in column A.

Can anyone help me on this ?

Hi,
This should do the trick


Sub FindNames()
Dim Range1(), Range2()
Dim bFound As Boolean
Dim RowNo As Integer


Range1 = Range("A1:" & Range("A1").End(xlDown).Address)
Range2 = Range("B1:" & Range("B1").End(xlDown).Address)

For i = 1 To UBound(Range1)
    bFound = False
    For j = 1 To UBound(Range2)
        If Range1(i, 1) = Range2(j, 1) Then
            bFound = True
            Exit For
        End If
    Next
    If bFound = False Then
        RowNo = RowNo + 1
        Sheets(2).Cells(RowNo, 1) = Range1(i, 1)
    End If
Next
RowNo = 0
For i = 1 To UBound(Range2)
    bFound = False
    For j = 1 To UBound(Range1)
        If Range1(j, 1) = Range2(i, 1) Then
            bFound = True
            Exit For
        End If
    Next
    If bFound = False Then
        RowNo = RowNo + 1
        Sheets(3).Cells(RowNo, 1) = Range2(i, 1)
    End If
Next

End Sub

-vemaju