Batch rename in MSDOS

mikaelpelle · #1 (**permalink**) November 21st, 2007, 01:21 AM

My camera is creating files like 01042007011.jpg (DAYMONTHYEARNUMBER.EXT).
I would like to create a batch file that rename them to YEARMONTHDAY_NUMBER.EXT, 20070401_011.jpg in my exemple.

As I don't have delimiters, except for the extension, i don't really know how to split the different elements of the filename. I've tried something like this:

Code:

@echo off

for /F "tokens=*" %%A in ('dir *.jpg *.mp4 /B') do (
 for /F "delims=. tokens=1" %%G in ("%%A") do (
     call :_rename %%G
 )
)

goto :_end

:_rename

set filenumber=%1
set filenumber=%filenumber:~-3%
echo %filenumber%

set year=%1
set year=%year:~+4%
echo %year%

:_end
endlocal

pause

This will return:
011 -> working
2007011 -> how to remove the 011 at the end ?

The tilde with the dash (~-) permits me to return only the last 3 characters of my strings. So its working fine to get the filenumber.
I tried to do it with ~+, but it then remove an amount of characters at the beginning. So it only returns the end of the string in both case. I haven't found a way to have only the day, month and year.

Thanks for your help.

mikaelpelle · #2 (**permalink**) November 27th, 2007, 05:18 AM

btw if it's not possible to do it in msdos, how can i do it ? =) thanks for your help.

mikaelpelle · #3 (**permalink**) November 27th, 2007, 11:04 AM

after hours, i finally manage to have my batch working =) i should have rename all my pictures manually one by one would have taken me less time hehe. anyways here's the working batch.

Code:

@echo off

for /F "tokens=*" %%A in ('dir *.jpg /B') do (
 for /F "delims=. tokens=1" %%G in ("%%A") do (
     call :_renamejpg %%G
 )
)
for /F "tokens=*" %%A in ('dir *.mp4 /B') do (
 for /F "delims=. tokens=1" %%G in ("%%A") do (
     call :_renamemp4 %%G
 )
)
goto :_end


:_renamejpg
set filenumber=%1
set filenumber=%filenumber:~-3%
set year=%1
set year=%year:~4,4%
set month=%1
set month=%month:~2,2%
set day=%1
set day=%day:~0,2%
ren %1.jpg %year%%month%%day%_%filenumber%.jpg
goto :eof

:_renamemp4
set filenumber=%1
set filenumber=%filenumber:~-3%
set year=%1
set year=%year:~4,4%
set month=%1
set month=%month:~2,2%
set day=%1
set day=%day:~0,2%
ren %1.mp4 %year%%month%%day%_%filenumber%.mp4
goto :eof

:_end
endlocal