Option Explicit
Option Base 0       ' Mandates that arrays’ LBound() = 0

Private arStrs()    As String   ' Array of strings.  Each concatenation 
                                ' puts ‘Text’ arg into a new element of 
                                ' this array.
Private curSz       As Long     ' Points to the element to receive
                                ' the Text of a Concatenation.
Private maxSz       As Long     ' Current count of elements 
                                ' in array.  Reading a var is faster than 
                                ' UBound().
Private delta       As Long     ' Number of new, empty strings to add to 
                                ' the array when class has run out of room.
Private NoLongerNew As Boolean  ' False until something is added to the 
                                ' internal data.

Private Sub Class_Initialize()
    maxSz = 100
    If delta = 0 Then delta = 50    ' ChunkSize might have been changed.  
                                    'Want to set delta only
                                    ' when this routine is called automa-
                                    ' tically by the class
    ReDim arStrs(maxSz - 1)         ' actually being initialized.
End Sub

Public Property Let ChunkSize(Value As Long)

    If Value < 1 Then _
        Err.Raise vbObjectError + 2, _
                  "clsStringBuilder_array", _
                  "ChunkSize cannot be less than 1."

    delta = Value

End Property

Public Property Get ChunkSize() As Long
    ChunkSize = delta
End Property

Public Property Let InitialSize(Value As Long)

    If Value < 1 Then _
        Err.Raise vbObjectError + 2, _
                  "clsStringBuilder_array", _
                  "InitialSize cannot be less than 1."

    If NoLongerNew Then _
        Err.Raise vbObjectError + 1, _
                  "clsStringBuilder", _
                  "The object already has data.  Cannot initialize."

    maxSz = Value
    ReDim arStr(maxSz - 1)  ' No Preserve required.

End Property

Public Sub Add(Text As String)

    If (curSz + 1) > maxSz Then
        maxSz = maxSz + delta
        ReDim Preserve arStrs(maxSz - 1)
    End If

    arStrs(curSz) = Text
    curSz = (curSz + 1)

    NoLongerNew = True

End Sub

Public Property Get Text() As String
    Text = Join(arStrs)
End Property

Public Sub Clear()
    NoLongerNew = False
    Class_Initialize  ' Re-initialize the object
End Sub