Option Explicit

Private Sub Command1_Click()
    Dim strField As String
    Dim lngItemCodePosition As Long

    ' Get field data (I am just using a string assignment for the example).
    strField = "HP Monitors: Item code: 1000000001. Location: Main" & vbCrLf & _
               "Epson Printers: Item code: 1000000002: Location: Springfield" & vbCrLf & _
               "Dell Dimension 2400: Item code: 1000000003. Location: Satellite" & vbCrLf & _
               "Brother HL - 5040 Printer: Item code: 1000000004: Location: Colesville"

    ' Initialize value
    lngItemCodePosition = 0

    ' This assumes that the length of the item code is always 10 digits (as in example).
    Do

        ' Instr will return the "next" position a value occurs at. It will return 0
        ' if the value does not exist (again).
        lngItemCodePosition = InStr((lngItemCodePosition + 1), strField, "Item code:")

        If lngItemCodePosition > 0 Then
            ' This assumes that the length of the item code is always 10 digits (as in example).
            Debug.Print "Item Code: " & Mid$(strField, lngItemCodePosition + 11, 10)
        End If

    Loop Until lngItemCodePosition = 0



    ' Re-Initialize value
    lngItemCodePosition = 1

    ' This assumes that the length of the item code can change, but that:
    ' 1) The item code is numeric (only).
    ' 2) There is a non numeric character after the item code.
    Dim strItemCode As String
    Dim strNextCharacter As String
    Do

        ' Instr will return the "next" position a value occurs at. It will return 0
        ' if the value does not exist (again).
        lngItemCodePosition = InStr((lngItemCodePosition), strField, "Item code:")

        ' Check that another item code existed.
        If lngItemCodePosition > 0 Then

            ' Account for the "Item code: " text.
            lngItemCodePosition = lngItemCodePosition + 11

            ' Initialize values
            strItemCode = ""
            strNextCharacter = Mid$(strField, lngItemCodePosition, 1)

            ' Loop through all the numeric values.
            Do While IsNumeric(strNextCharacter)

                ' Build the item code.
                strItemCode = strItemCode & strNextCharacter

                ' Increment so we can look at the next character.
                lngItemCodePosition = lngItemCodePosition + 1

                ' Get the next character.
                strNextCharacter = Mid$(strField, lngItemCodePosition, 1)

            Loop

            Debug.Print "Item Code: " & strItemCode
        End If

    Loop Until lngItemCodePosition = 0

End Sub