I'm trying to verify a website is up or down by retrieving the status code using vbScript. I've seen the following example several times on the web, but get "unspecified error" for the line "strPageStat = Http.Status"

Below is the code. Any ideas on the error or another way to check if the website is functioning?

msgbox urlget("http://www.google.com")
Dim strPageStat

Function URLGet(URL)
  Set Http = CreateObject("Microsoft.XMLHTTP")
  Http.Open "GET", URL, True
  Http.Send ()
  strPageStat = Http.Status
  if strPageStat = "200" then
      URLGet="Error:"& strPageStat
      else
      ' URLGet = Http.ResponseBody
      URLGet = Http.responseText
  end if
  End Function

You are trying to make the call *asynchronously* (which means "don't wait for the answer") and so then you are trying to get the status before the answer is received. So of course you get the error.

Also, you test on the status is backwards. "200" means "ok".

So...

<script language="VBScript">

msgbox urlget("http://www.google.com")
Dim strPageStat

Function URLGet(URL)
  Set Http = CreateObject("Microsoft.XMLHTTP")
  Http.Open "GET", URL, False ' False means *synchronous*
  Http.Send ()
  strPageStat = Http.Status
  if strPageStat <> "200" then
      URLGet="Error:"& strPageStat
  else
      URLGet = Http.responseText
  end if
End Function
</script>

If you really want to do this asynch, you need to use the same kind of state change handler you would for Ajax.

Thanks, that worked.