Parsing xml using vbscript

saisudrik · #1 (**permalink**) February 27th, 2009, 05:57 AM

Hi,

I need to parse a particular node in an xml file to get all the nodes and childnodes of each node under a particular node.
Can anyone help me with the code?
I found a function on devguru.com and i have modified it a bit. But gives error 'Object not a collection' code: 800A01C3

Code:

Sub Drill(n) 
  msgbox(n.nodeName & "<br>") 
  cc = 0 
  while n.hasChildNodes 
    cc = cc + 1 
    set chd = n.childnodes 
    for each cld1 in chd 
      msgbox(cld1.nodeName) 
      for each att in cld1.attributes 
        msgbox(cld1.nodeName & " " & att.name & " " & att.value) 
      next 
      If cld1.nodeName = "AName" Then 
        msgbox("AName "& cld1.Text) 
      End If 
      Drill(cld1) 
    next 
  wend 
End Sub

Old Pedant · #2 (**permalink**) February 27th, 2009, 07:40 PM

Doesn't make sense.

You are in an INFINITE LOOP there.

Code:

while n.hasChildNodes

You never break out of that loop and you never change the value of n inside the loop.

Also, since you are using recursion you *MUST* DIM each of the variables that are local to each occurrence of the recursion INSIDE the SUB.

That would mean

Code:

Sub Drill(n) 
    Dim chd, cld1, att
    ...

Finally, you are not checking to be sure that some of those values *exist* before you use them! For example, you do

Code:

for each att in cld1.attributes

But you *WILL* get an error if cld1 doesn't HAVE any attributes!

Old Pedant · #3 (**permalink**) February 27th, 2009, 08:03 PM

See if this works:

Code:

Sub ShowOneNode( theNode ) 
    Dim atts, att, nodeinfo
    nodeinfo = theNode.NodeName

    Set atts = theNode.Attributes
    If Not ( atts Is Nothing ) Then
        For Each att In atts
            nodeinfo = nodeinfo & " [" & att.Name & "=" & att.Value & "]"
        Next
    End If
    MsgBox( "Node: " & nodeinfo )
    
    Dim kids, kid
    Set kids = theNode.ChildNodes
    If Not ( kids Is Nothing ) Then
        For Each kid In kids
            ShowOneNode( kid )
        Next
    End If
End Sub

All off the top of my head and untested. If you hand me a sample XML file, though, I'd be willing to test it out.