Return Largest Number

Neal · September 15th, 2006, 03:52 AM

Hi,

I am trying to return the largest number of 'Sets' for each 'Test' in the XML example below, using my XSL schema.

In the edited example, the value returned should be '3', as there are 3 Sets for Test 0900 and only 2 Sets for Test 0901. How do I return the largest value '3' using XSL?

Can anyone help please?

XML

Code:

<Test Code="0900">
 <UOM>%</UOM>
 <Desc>NIR Moisture</Desc>
 <Set No="1">
  <Targ/>
  <Min/>
  <Max/>
 </Set>
 <Set No="2">
  <Targ/>
  <Min/>
  <Max/>
 </Set>
 <Set No="3">
  <Targ/>
  <Min/>
  <Max/>
 </Set>
</Test>
<Test Code="0901">
 <UOM>%</UOM>
 <Desc>NIR Oil</Desc>
 <Set No="1">
  <Targ/>
  <Min/>
  <Max/>
 </Set>
 <Set No="2">
  <Targ/>
  <Min/>
  <Max/>
 </Set>
</Test>

XSL

Code:

<xsl:template name="SampleDetails">
 <xsl:element name="NumberOfTestsRequired">
  <xsl:for-each select="*//Test">
   <xsl:for-each select=".//Set">

    <xsl:if test="position() =last()">    
     <xsl:value-of select="."/>
    </xsl:if>
   </xsl:for-each>
  </xsl:for-each>
 </xsl:element>
</xsl:template>

Many thanks,

Neal

A Northern Soul

mhkay · September 15th, 2006, 04:18 AM

In 2.0:

max(for $x in Test return count($x/Set))

In 1.0:

<xsl:variable name="max">
  <xsl:for-each select="Test">
     <xsl:sort select="count(Set)" data-type="number"/>
     <xsl:if test="position()=last()">
         <xsl:value-of select="count(Set)"/>

In both cases this assumes the parent of the Test elements is the context node.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Neal · September 15th, 2006, 04:48 AM

Many thanks Mike,

Excellent response for both versions (I needed 1.0).

The actual XSL code I used was:

Code:

<xsl:template name="SampleDetails">
 <xsl:element name="NumberOfTestsRequired">
  <xsl:variable name="max"/>
   <xsl:for-each select=".//Test">
    <xsl:sort select="count(Set)" data-type="number"/>
     <xsl:if test="position()=last()">
      <xsl:value-of select="count(Set)"/>
     </xsl:if>                    
   </xsl:for-each>
 </xsl:element>
</xsl:template>

Just one thing, why was the variable 'Max' needed?

Neal

A Northern Soul

mhkay · September 15th, 2006, 05:28 AM

You didn't say what you wanted to do with value once you had computed it, so I put it in a variable for you. If you just want to output it, that's not necessary.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference