Hi all

Newbie to the forum (and to XSL/T :)) and i have a problem that i'm hoping someone can help me with.

I have an XML attribute that is seperated by commas(,) and pipes(|). Here's a small sample...

CC_DESCRIPTION="D686,Work,1|E004,English,2|E005,En glish,2|E012,Media,1|E231,Business Technology,1|E280,Applied Technology,1|E282,Technical Graphics,1| etc etc "

What I need to do is create 2 HTML tables with each pipe(|) seperated set of values in a new row and each comma(,) seperated value in it's own cell.

Ie..

<table>
  <tr>
    <td>D686 (code)</td>
    <td>Work (title)</td>
    <td>1 (points)</td>
  </tr>
  <tr>
    <td>E004 (code)</td>
    <td>English (title)</td>
    <td>2 (points)</td>
  </tr>
</table> etc etc

I've done this, however, all the values are in 1 table - what I need to do is now split the data - all codes starting with 'E' should be in a seperate table to those starting with 'E'.

I'm completely baffled. Any help would be appreciated.

BTW, I have no control over the layout of the XML...only the XSL.

Thanks in advance,
Perry

Hi Perry,

The trick is to use recursive templates to parse the string, not trivial but the following works.

xml:
<A B="D686,Work,1|E004,English,2|E012,Media|1" />

xslt:
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <xsl:template match="/">
      <table border="1">


         <xsl:call-template name="parse-row">
            <xsl:with-param name="rows">
               <xsl:value-of select="A/@B" />
            </xsl:with-param>
         </xsl:call-template>
      </table>
   </xsl:template>

   <xsl:template name="parse-row">
      <xsl:param name="rows" />


      <xsl:variable name="this-row">
         <xsl:choose>
            <xsl:when test="contains($rows, '|')">
               <xsl:value-of select="substring-before($rows, '|')" />
            </xsl:when>
            <xsl:otherwise>
               <xsl:value-of select="$rows" />
            </xsl:otherwise>
         </xsl:choose>
      </xsl:variable>


      <xsl:variable name="rows-left" select="substring-after($rows, '|')" />

      <xsl:if test="string-length($this-row)!=0">
         <tr>

            <xsl:call-template name="parse-cells">
               <xsl:with-param name="cells">
                  <xsl:value-of select="$this-row" />
               </xsl:with-param>
            </xsl:call-template>
         </tr>
      </xsl:if>


      <xsl:if test="string-length($rows-left)!=0">
         <xsl:call-template name="parse-row">
            <xsl:with-param name="rows">
               <xsl:value-of select="$rows-left" />
            </xsl:with-param>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>

   <xsl:template name="parse-cells">
      <xsl:param name="cells" />

      <xsl:variable name="this-cell">
         <xsl:choose>
            <xsl:when test="contains($cells, ',')">
               <xsl:value-of select="substring-before($cells, ',')" />
            </xsl:when>

            <xsl:otherwise>
               <xsl:value-of select="$cells" />
            </xsl:otherwise>
         </xsl:choose>
      </xsl:variable>

      <xsl:variable name="cells-left">
         <xsl:value-of select="substring-after($cells, ',')" />
      </xsl:variable>

      <td>
         <xsl:value-of select="$this-cell" />
      </td>

      <xsl:if test="string-length($cells-left)!=0">
         <xsl:call-template name="parse-cells">
            <xsl:with-param name="cells">
               <xsl:value-of select="$cells-left" />
            </xsl:with-param>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>
</xsl:stylesheet>

Regards
Bryan