a bold word in a selected sentence

Birger · September 8th, 2004, 11:23 AM

Wonder if I can do this with xsl-fo:

If I pull this element from my xml-source:
<para>How do <b>you</b> do</para>

using a
..select="para"

from my xsl, then how do I format the single word 'you' into bold, italic or whatever?

Could anyone explain the procedure to achieve this?

Thanks in advance!

//Forgot to mention, I transform to pdf with FOP!

Birger · September 10th, 2004, 03:19 PM

Ask and ye shall find.

Easy, if you know how to. For anyone interested:

    <xsl:template match="b">
        <fo:inline font-weight='bold'><xsl:apply-templates/></fo:inline>
    </xsl:template>

Biology Girl · December 31st, 2006, 10:04 PM

I searched and found this old post, which directly answers my question... except I cannot get it to work. I know I am making a fundamental mistake, but I just don't know where.

In the XML code below, how do I print out the contents defined by the element "concept" while italicizing the equation delimited by the identifier "math"? What would the XSLT file look like?

<?xml version="1.0" encoding="ISO-8859-1" ?>
<?xml-stylesheet type="text/xsl" href="lessonplan.xsl"?>

<standard number="2.12.7">
<concept>
   Consider the equation <math>x + y = 3</math>.
</concept>
</standard>

Here is the lessonplan.xsl file I wrote, without the attempt to italicize the equation:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fo="http://www.w3.org/1999/XSL/Format">

<xsl:template match="/">
  <html>
  <body>
    <h2>Lesson Plan</h2>
    <xsl:value-of select="//concept"/>
  </body>
  </html>
</xsl:template>
</xsl:stylesheet>

Thanks.

mhkay · January 1st, 2007, 06:13 AM

Use template rules:

<xsl:template match="/">
  <html>
  <body>
    <h2>Lesson Plan</h2>
    <xsl:apply-templates/>
  </body>
  </html>
</xsl:template>

<xsl:template match="concept">
<p><xsl:apply-templates/></p>
</xsl:template>

<xsl:template match="math">
<i><xsl:apply-templates/></i>
</xsl:template>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Biology Girl · January 1st, 2007, 07:02 PM

Thanks, it works. Strange how I found so little information on inline formatting on the Web. It seems as that would be a very common formatting technique.