select question

sgruhier · February 28th, 2005, 04:13 AM

Hi,

I have a easy XSL question, I would like to transform this XML:

<?xml version="1.0" encoding="ISO-8859-1"?>
<lf>
     <a>this is a link <b url="google.com">google</b> to a search engine</a>
</lf>

To get this:

<?xml version="1.0" encoding="UTF-8"?>
<text>this is a link to a search engine</text>
<link url="google.com">google</link>

I have done this XSL:

<xsl:template match="a">
    <xsl:element name="text">
        <xsl:value-of select="text()"/>
     </xsl:element>
   <xsl:apply-templates select="b"/>
</xsl:template>

<xsl:template match="b">
    <xsl:element name="link">
        <xsl:attribute name="url"><xsl:value-of select="@url"/></xsl:attribute>
        <xsl:value-of select="."/>
    </xsl:element>
</xsl:template>

The result is

<?xml version="1.0" encoding="UTF-8"?>
<text>this is a link </text>
<link url="google.com">google</link>

But I lost the end of the text of the <a> tag ("to a search engine").
Any idea?
Thanks
Seb

joefawcett · February 28th, 2005, 05:10 AM

A quick fix, replace:

Code:

<xsl:value-of select="text()"/>

with

Code:

<xsl:apply-templates select="text()"/>

Your styleshhet could be simplified, if you don't need full control over the result elements, by using literal result elements:

Code:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="a">
    <text>
      <xsl:apply-templates select="text()"/>  
    </text>
    <xsl:apply-templates select="b"/>
  </xsl:template>

  <xsl:template match="b">
    <link url="{@url}">
      <xsl:value-of select="."/>
    </link>
  </xsl:template>
</xsl:stylesheet>

--

Joe (Microsoft MVP - XML)

mhkay · February 28th, 2005, 10:10 AM

Don't use

<xsl:value-of select="text()"/>

use

<xsl:value-of select="."/>

The first selects only the first text node child, which you almost never want.

Alternatively, you might want <xsl:copy-of select="."/> or <xsl:apply-templates/> - that depends on your requirements

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference