converting self-nested xml to html

its_vippy · May 30th, 2005, 09:56 PM

Hi
My xml file is

Code:

<layout>
    <frameset split="rows" sizes="200,200,600">
        <frame name="headerFrame" size="200" src="" resize="false"></frame>
        <frame name="menuFrame" size="200" src=""  resize="false"></frame>
        <frame name="downFrame" size="600" src=""  resize="false"></frame>
    </frameset>
</layout>

and i m using a xsl to convert it to html frameset which is :

Code:

<xsl:template match="/">
    <html>
    <head><title>Samsung OAMP</title></head>

        <xsl:apply-templates select="/layout/frameset" />

    </html>
</xsl:template>
<xsl:template match="frameset">
<frameset>
    <xsl:if test="@split='rows'">
        <xsl:attribute name="rows">
            <xsl:value-of select="@sizes"/>
        </xsl:attribute>
    </xsl:if>
    <xsl:if test="@split='cols'">
        <xsl:attribute name="cols">
            <xsl:value-of select="@sizes"/>
        </xsl:attribute>
    </xsl:if>
        <xsl:for-each select="frame">
            <frame name="{@name}" src="{@src}" noresize="{@resize}"></frame>         
        </xsl:for-each>
    </frameset>
</xsl:template>

the problem is if i change xml file to have <frameset> within another <frameset>like

Code:

<frameset>
<frame></frame>
<frame></frame>
<frameset></frameset>
</frameset>

what changes should i make in xml file
Any help is appreciated

barcher · June 1st, 2005, 04:47 AM

Try the following:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:template match="/">
      <html>
         <head>
            <title>Samsung OAMP</title>
         </head>

         <xsl:apply-templates select="/layout/frameset" />
      </html>
   </xsl:template>

   <xsl:template match="frameset">
      <frameset>
         <xsl:if test="@split='rows'">
            <xsl:attribute name="rows">
               <xsl:value-of select="@sizes" />
            </xsl:attribute>
         </xsl:if>

         <xsl:if test="@split='cols'">
            <xsl:attribute name="cols">
               <xsl:value-of select="@sizes" />
            </xsl:attribute>
         </xsl:if>

         <xsl:apply-templates />
      </frameset>
   </xsl:template>

   <xsl:template match="frame">
        <frame name="{@name}" src="{@src}" noresize="{@resize}">
            <xsl:apply-templates />
        </frame>
   </xsl:template>

</xsl:stylesheet>