XML document "file name"

schurli · August 28th, 2003, 12:10 AM

I wonder if there is a possibility to get the actual xml
document's "file name" in a variable?

I'm dealing with xml documents stored on local disk or share, and
would like to know the document's file name during xslt.

Regards
George

pgtips · August 28th, 2003, 03:18 AM

I don't know of any mechanism within xsl to find this out, but presumably the process that invokes the transformation knows what the filename is, so can't you just pass the filename in as a parameter?

rgds
Phil

schurli · August 28th, 2003, 04:35 PM

I am using the MSXML 3 or 4 parser from VB:

Syntax:
strValue = oXMLDOMNode.transformNode(objStylesheet)

The actual statement:
yDoc.loadXML xdoc.transformNode(xslStyleSheet)

Does anybody know how I can here pass a parameter to the stylesheet execution?

Regards,
George

armmarti · August 29th, 2003, 02:15 AM

IXSLProcessor.addParameter method (MSXML4) achieves that.

Look at this URL: http://msdn.microsoft.com/library/de...th_ac_5pgy.asp

Here the code is different a little, but I hope it will give some guide.

Regards,
Armen

pgtips · August 29th, 2003, 03:59 AM

George, here's a function I use regularly to run XSL transformations with parameters:

Code:

Sub DoXslt(sXml, sFileXslt, dctParams)
'==============================================================
' Function : DoXslt
' Purpose : performs an XSLT transformation with parameters
' Author : Phil Griffiths
' Parameters : sXml - the xml string
'         : sFileXslt - relative filename of XSLT
'            : dctParams - Scripting.Dictionary containing param name/value pairs
' Globals : Response object
' Return : None - transformation result written to Response
' Mods : PG 16/4/2002 - Initial Version
'==============================================================
    Dim domXml, domXslt, xslt, xslProc, vKey

    If Len(sXml) > 0 And Len(sFileXslt) > 0 Then
        Set domXml = LoadXmlIntoDom(cProgIdMsxml, sXml)
        Set domXslt = LoadXmlFileIntoDom(cProgIdMsxmlFreeThread, Server.MapPath(sFileXslt))

        Set xslt = Server.CreateObject(cProgIdXslTemplate)
        With xslt
            Set .stylesheet = domXslt
            Set xslProc = .createProcessor()
        End With

        With xslProc
            .input = domXml
            .output = Response
            If Not dctParams Is Nothing Then
                For Each vKey in dctParams
                    Call .addParameter(vKey, dctParams(vKey))
                Next
            End If
            .Transform
        End With

        Set xslProc = Nothing
        Set xslt = Nothing
        Set domXml = Nothing
        Set domXslt = Nothing
    End If

End Sub

You'll need these useful supporting functions and constants too

Code:

Const cProgIdMsxml = "MSXML2.DOMDocument.4.0"
Const cProgIdMsxmlFreeThread = "MSXML2.FreeThreadedDOMDocument.4.0"
Const cProgIdXslTemplate = "MSXML2.XSLTemplate.4.0"
Const cProgIdDictionary = "Scripting.Dictionary"

Function LoadXmlIntoDom(sProgId, sXml)
'==============================================================
' Function : LoadXmlIntoDom
' Purpose : loads an xml string into a DOM object
' Author : Phil Griffiths
' Parameters : sProgId - of the XML DOM object to create
'             : sXml - the xml string
' Globals : None
' Return : object specified by sProgId
' Mods : PG 15/4/2002 - Initial Version
'==============================================================
    Set LoadXmlIntoDOM = Server.CreateObject(sProgId)
    LoadXmlIntoDOM.async = False
    Call LoadXmlIntoDOM.loadXML(sXml)
    Call LoadXmlIntoDOM.setProperty("SelectionLanguage", "XPath")

End Function

Function LoadXmlFileIntoDom(sProgId, sXmlFilePath)
'==============================================================
' Function : LoadXmlIntoDom
' Purpose : loads an xml file into a DOM object
' Author : Phil Griffiths
' Parameters : sProgId - of the XML DOM object to create
'         : sXmlFilePath - the path of the xml file
' Globals : None
' Return : object specified by sProgId
' Mods : PG 15/4/2002 - Initial Version
'==============================================================
    Set LoadXmlFileIntoDOM = Server.CreateObject(sProgId)
    LoadXmlFileIntoDOM.async = False
    Call LoadXmlFileIntoDOM.load(sXmlFilePath)
    Call LoadXmlFileIntoDOM.setProperty("SelectionLanguage", "XPath")

End Function

If you put these functions into an include file, then all you need in your asp is something like this to run any transformation with parameters

Code:

Dim dctParams
Set dctParams = Server.CreateObject(cProgIdDictionary)
With dctParams
  .Add "ParamName1", "ParamValue1"
  .Add "ParamName2", "ParamValue2"
  ' etc...
End With
Call DoXslt(sXmlData, "xslt/thefile.xsl", dctParams)

Set dctParams = Nothing

hth
Phil

schurli · August 30th, 2003, 03:20 AM

Hi all,

thanks a lot for your replies and code samples.

Now I'm quite sure I'll find my way :-)

Regards,
George