Hi,

I am trying to apply an XSLT stylesheet to convert a source XML Doc into a HTML Checkbox TAG. The source XML can have a number of attributes. Hence i want to loop thry the sourcenode's attributes and add it to the output HTML <INPUT> TAG's attributes.
The source XML
<?xml version="1.0" encoding="iso-8859-1"?>
<ww:checkbox name='' value='' required='no' selected='no' message='the field is not selected'/>

The XSLT
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ww='http://www.fitpro.com'>
<xsl:output method="html"/>
 <xsl:template match="/">
 <xsl:apply-templates/>
</xsl:template>
<xsl:template match="ww:checkbox">
    <xsl:element name="input">
        <xsl:attribute name='type'>checkbox</xsl:attribute>
        <xsl:attribute name='name'>
            <xsl:value-of select="@name"/>
        </xsl:attribute>
        <xsl:attribute name='value'>
            <xsl:value-of select="@value"/>
        </xsl:attribute>
        <xsl:for-each select="attribute::*">
            <xsl:attribute name="name(.)"><xsl:value-of select="."/></xsl:attribute>
</xsl:for-each>
        </xsl:element>
  </xsl:template>
</xsl:stylesheet>


THE OUTPUT IS
=<input xmlns:ww="http://www.fitpro.com" type="checkbox" name="checkbox1" value="agree"> But i want all the other attributes sych as required, selected, message etc to appear in the output. Is that possible?

I corrected two errors:

(a) added a namespace declaration in the source XML

(b) changed <xsl:attribute name="name(.)"> to <xsl:attribute name="{name(.)}">

and it gave the required output. Without the curly braces the attribute has an invalid name, and the XSLT 1.0 spec allows silent recovery from that error by simply ignoring the attribute. I expect that's what happened to you.

However you can achieve the result more easily by writing the template body as:

<input><xsl:copy-of select="@*"/></input>



Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Thanks for that. I was seeing this curly brackets in some samepl code but did not figure out its importance. That was very very helpful. I am trying to develop an XML/XSLT driven Presentation layer framework components in CFC for some CFMX based applications and integrate it into a fusebox framework. My next step is to go a grab a copy of your XSLT and XPath Books..

Many thanks
Sathish Kumar