Hi,

Imagine that I have the following XML document:

<article>
    <heading level="1">Heading1</heading>
    <heading level="2">Sub1</heading>
    <paragraph>1st <bold>block</bold> of info</paragraph>
    <heading level="1">Heading2</heading>
    <heading level="2">Sub2</heading>
    <paragraph>2nd <italic>block</italic> of info</paragraph>
    <heading level="1">Heading3</heading>
    <heading level="2">Sub3</heading>
    <paragraph>3rd <strong>block</strong> of info</paragraph>
</article>

and I want to transform it into :


<article>
    <section>
        <heading>Heading1</heading>
        <sub-heading>Sub1</sub-heading>
        <paragraph>1st <bold>block</bold> of info</paragraph>
    </section>
    <section>
        <heading>Heading2</heading>
        <sub-heading>Sub2</sub-heading>
        <paragraph>2nd <italic>block</italic> of info</paragraph>
    </section>
    <section>
        <heading>Heading3</heading>
        <sub-heading>Sub3</sub-heading>
        <paragraph>3rd <strong>block</strong> of info</paragraph>
    </section>
</article>

I am using the following XSL :

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/article">
    <article>
        <xsl:apply-templates select="heading" />
    </article>
</xsl:template>

<xsl:template match="heading">
    <xsl:choose select=".">
        <xsl:when test ="@level &lt; 2">
            <xsl:element name="section">
                <xsl:element name="heading">
                    <xsl:value-of select="." />
                </xsl:element>
                <xsl:apply-templates select="following-sibling::*" />
            </xsl:element>
        </xsl:when>
        <xsl:otherwise>
            <xsl:element name="sub-heading">
                    <xsl:value-of select="." />
            </xsl:element>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Unfortunately, it is not producing the desired result because I need it to stop at each "heading".

Does anyone have any ideas about how I can achieve my goal (without resorting to writing parsing code).

Thanks,

Simon

The problem is known as "positional grouping" and you'll find examples if you google for that. In 2.0 it's done using

<xsl:for-each-group group-starting-with="pattern">

which you need to apply at each level of heading.

In 1.0 the two common techniques are

(a) reduce it to a value-based grouping problem, where the grouping key is generate-id(preceding-sibling::heading[@level='1'][1]) - you can then use Muenchian grouping using this key

(b) do "sibling recursion" where you process the siblings using <xsl:apply-templates select="following-sibling::*[1]"> - I'll leave you to find examples of that in the various FAQs and tutorials.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Hi Michael,

Thanks for your help. I feel that I am a lot closer now using the following XSL:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:key name="paras" match="paragraph | link | heading[@level=2]"
         use="preceding-sibling::heading[1]/text()" />

<xsl:template match="article">
  <article>
    <xsl:apply-templates select="heading[@level=1]" />
  </article>
</xsl:template>

<xsl:template match="heading[@level=1]">
  <xsl:element name="section">
      <xsl:copy-of select="." />
         <xsl:copy-of select="key('paras', text())" />
  </xsl:element>
</xsl:template>

</xsl:stylesheet>


However, I have a problem with "level 2 headers". Using the following XML with all of the level 2 headers commented out, all is well. However, as soon as the first level 2 header ("sub 1") is uncommented, the first section processes nothing past the first level 2 header and ONLY the paragraph element is processed in the other sections. When I replaced the level 2 headers with the element "subheading" that was fine (although I cannot do this in the final solution).

The text.xml file is :

<article>
    <heading level="1">Heading1</heading>

    <paragraph>1st <bold>block</bold> of info</paragraph>
    <paragraph>Sneaky</paragraph>
    <link>Points somewhere</link>
    <heading level="1">Heading2</heading>

    <paragraph>2nd <italic>block</italic> of info</paragraph>
    <heading level="1">Heading3</heading>

    <paragraph>3rd <strong>block</strong> of info</paragraph>
</article>

Any help would be appreciated.

Thanks,

Simon

Ooooops. Found the error (must remember to check code more thoroughly before posting replies).
The offending line has been altered from:

   use="preceding-sibling::heading[1]/text()" />

to:

   use="preceding-sibling::heading[@level=1][1]/text()"

See below:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:key name="paras" match="paragraph | link | heading[@level=2]"
         use="preceding-sibling::heading[@level=1][1]/text()" />

<xsl:template match="article">
  <article>
    <xsl:apply-templates select="heading[@level=1]" />
  </article>
</xsl:template>

<xsl:template match="heading[@level=1]">
  <xsl:element name="section">
      <xsl:copy-of select="." />
         <xsl:copy-of select="key('paras', text())" />
  </xsl:element>
</xsl:template>

</xsl:stylesheet>

Thanks for your help.