Given a school xml file: it contains attributes of name and district
<?xml version="1.0" encoding="utf-8"?>
<School name="Joy" district="Albany">
<Class>A</Class>
<Teacher>Dave</Teacher>
</School>

I want to have an identity copy without "Class" element and force the district attribute a value of "NY". I thought following stylesheet should work, but it fails to defalut the attribute value:

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="@*|node()">
   <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
   </xsl:copy>
</xsl:template>


<xsl:template match="Class"/>


<xsl:template match="School[@district]">
  <xsl:copy>
    <xsl:attribute name="district">NY</xsl:attribute>
    <xsl:apply-templates select="@*|node()" />
  </xsl:copy>
</xsl:template>
</xsl:stylesheet>

That is, running the school xml file above, I would expect following:
<?xml version="1.0" encoding="utf-8"?>
<School name="Joy" district="NY">
<Teacher>Dave</Teacher>
</School>

Instead the result is:
<?xml version="1.0" encoding="utf-8"?>
<School district="Albany" name="Joy">
<Teacher>Dave</Teacher>
</School>

That's the district attribute still remains as "Albany" instead of the desired "NY". What to do?

The apply-templates select="@*" is causing the district attribute to be copied, and when you write two attributes with the same name to the same element, the last one wins.

Add

<xsl:template match="@district"/>

to your stylesheet.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference