following-sibling assistance needed

djmarquette · March 9th, 2006, 10:27 AM

Hello,

I have searched the forums and can't seem to find a fix for my need yet. I am stepping through an XML document and trying to pull the content (text) of two siblings together into one.

First the data:

Code:

<Body>
    <Para>ARTICLE 1</Para>
    <Para>BILL OF RIGHTS</Para>
    <otherNode>other text</otherNode> . . .

I am creating a single element node with the text of the Para's concatenated and centered. So I want my output to be like this:

<Para Justify="Center">ARTICLE 1 BILL OF RIGHTS</Para>

I match on the first Para, start building my element, and then bring in the text. Here's my attempt:

Code:

<xsl:template match="Para">
    <xsl:element name="Para">
        <xsl:attribute name="Justify" select="'Center'"/>
        <xsl:value-of select="."/>
        <xsl:text> </xsl:text>
        <xsl:value-of select="following-sibling::*[1]" />
    </xsl:element>
</xsl:template>

I receive an error on the following-sibling line above, the error is "Error in XPath 2.0 expression (Not a node item)". I have tried multiple efforts based on tips from this forum, including 'following-sibling::Para[1]' and 'following-sibling::*[position()=1]' and even 'Para[1]/text()' all to no avail.

Are there any suggestions? I'd like to think I'm at least 'close'. Thank you in advance for any and all assistance.

Dan

mhkay · March 9th, 2006, 11:51 AM

Your code looks fine to me, what XSLT 2.0 processor are you using?

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

djmarquette · March 9th, 2006, 02:08 PM

Thank you for replying, Michael. And you are correct, in that it does work.

In my effort to be brief in my example, I left out part of the template that appears to be extremely relevant. I am creating this element as a result of mathing a regular expression string. So the prior code should have shown that it was nested within an <analyze-string> rule. The full code was thus:

Code:

    <xsl:template match="Para">
        <xsl:analyze-string select="text()" regex="(ARTICLE) (\d+)">
            <xsl:matching-substring>
                <xsl:element name="Para">
                    <xsl:attribute name="Justify" select="'Center'" />
                    <xsl:value-of select="."/>
                    <xsl:text> </xsl:text>
                    <xsl:value-of select="following-sibling::*[1]"/>
                </xsl:element>
            </xsl:matching-substring>
            <xsl:non-matching-substring /> 
        </xsl:analyze-string>
    </xsl:template>

I have remedied by building my new heading line into a variable outside of the <analyze-string> block and then referencing the variable when needed.

Code:

    <xsl:template match="Para">
        <xsl:variable name="artHeading" select="concat(text(), ' ', following-sibling::*[1])" />
        <xsl:analyze-string select="text()" regex="(ARTICLE) (\d+)">
            <xsl:matching-substring>
                <xsl:element name="Para">
                    <xsl:attribute name="Justify" select="'Center'" />
                    <xsl:value-of select="$artHeading"/>   
                </xsl:element>
            </xsl:matching-substring>
            <xsl:non-matching-substring />    
        </xsl:analyze-string>
    </xsl:template>

I am still puzzled why the following-sibling axis did not work within the <analyze-string> element.

Is there a cleaner way to achieve what I am trying to achieve?

Regards,
Dan

mhkay · March 9th, 2006, 02:54 PM

Yes, this difference is highly relevant. xsl:analyze-string changes the context item, and any axis expression (following-sibling included) starts from the context item, which must be a node.

the solution is

<xsl:variable name="x" select="."/>

outside the xsl:analyze-string, and

$x/following-sibling::*

inside it.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference