Hi all,

I have some problem in selecting the nodes by using the in-order traversal.

Here is my xml

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <project>
        <project_id>100</project_id>
        <parent_id>100</parent_id>
        <name>Project 1</name>
    </project>
    <project>
        <project_id>104</project_id>
        <parent_id>102</parent_id>
        <name>Phase 4.2</name>
    </project>
        <project>
        <project_id>105</project_id>
        <parent_id>100</parent_id>
        <name>release 1</name>
    </project>

    <project>
        <project_id>101</project_id>
        <parent_id>100</parent_id>
        <name>release 1</name>
    </project>
    <project>
        <project_id>102</project_id>
        <parent_id>100</parent_id>
        <name>Phase 4</name>
    </project>
    <project>
        <project_id>103</project_id>
        <parent_id>102</parent_id>
        <name>Phase 4.1</name>
    </project>
</root>

and my xslt is

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="root">
        <xsl:apply-templates select="project"></xsl:apply-templates>
    </xsl:template>

    <xsl:template match="project">
        <xsl:value-of select="project_id"></xsl:value-of>
        <xsl:variable name="pid" select="project_id"/>
        <xsl:apply-templates select="/root/project[$pid=current()]"></xsl:apply-templates>
        <xsl:text>#xa;</xsl:text>
    </xsl:template>
</xsl:stylesheet>

The output that i want to get is

100
105
101
102
104
103

But I am not able to traverse the tree and iam getting output as

100
104
105
101
102
103

I am stuck out here. Please any one help me.

__________________
Regards,
dsekar_nat

It's a bit hard to see what's going on because the XML you posted isn't well-formed.

I would expect your "root" template not to process all the child projects, but only the one that you know to be a top-level project. And your code for processing a project by finding its logical children looks quite wrong:

<xsl:apply-templates select="/root/project[$pid=current()]">

I would have expected to see

<xsl:apply-templates select="/root/project[parent_id=$pid]">

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Hi kay,

Thanks

Its working fine.

This is the xsl template I have used.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:variable name="projects" select="/root/project"/>
    <xsl:template match="root">
        <xsl:for-each select="project">
            <xsl:if test="project_id = parent_id">
                <xsl:apply-templates select="."/>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>

    <xsl:template match="project">
        <xsl:value-of select="project_id"/>
        <xsl:variable name="pi" select="project_id"/>
        <xsl:apply-templates select="/root/project[parent_id = $pi and project_id != $pi]"></xsl:apply-templates>
        <xsl:text>#xa;</xsl:text>
    </xsl:template>
</xsl:stylesheet>

It would be better coding style, I think, to replace

<xsl:for-each select="project">
            <xsl:if test="project_id = parent_id">
                <xsl:apply-templates select="."/>
            </xsl:if>
        </xsl:for-each>


with

<xsl:apply-templates select="project[project_id = parent_id]"/>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference