alternate ordering

pgtips · October 2nd, 2003, 04:45 AM

I assume it won't work "out of the box" with msxml because of armen's comment

Quote:

quote:I used Saxon 6.5.2, which performs RTF to nodeset conversion implicitly if the version is set to 1.1; you may need to perform the conversion explicitly by using the EXSLT's node-set function or something similar.

which refers to the groups variable. You need to use the msxsl:node-set() function, so you would replace <xsl:with-param name="set" select="$groups/*"/> with <xsl:with-param name="set" select="msxsl:node-set($groups)/*"/>

armen - any comments?

hth
Phil

pgtips · October 2nd, 2003, 04:50 AM

Forgot to mention that in order to use the msxsl:node-set() function you'll need to add a declaration of that namespace to the xsl:stylesheet element. The namespace you need is xmlns:msxsl="urn:schemas-microsoft-com:xslt"

polecat · October 2nd, 2003, 05:17 AM

hmmm... now intead of "expression must evaluate to a node-set" I get "exception occurred". Interestingly it still works in Netscape, I wasn't expecting Netscape to understand the MSXML specific call.

Here is the modified stylesheet

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt">

    <xsl:key name="number-to-person" match="person" use="number"/>
    <xsl:template match="/">
        <xsl:variable name="groups">
            <xsl:for-each select="/persons/person[generate-id() = generate-id(key('number-to-person', number)[1])]">
                <xsl:sort select="number"/>
                <xsl:variable name="current-group" select="/persons/person[number = current()/number]"/>
                <group>
                    <count>
                        <xsl:value-of select="count($current-group)"/>
                    </count>
                    <xsl:for-each select="$current-group">
                        <xsl:copy-of select="."/>
                    </xsl:for-each>
                </group>
            </xsl:for-each>
        </xsl:variable>

        <xsl:variable name="max-count">
            <xsl:call-template name="get-max">
                <xsl:with-param name="set" select="msxsl:node-set($groups)/*"/>

            </xsl:call-template>
        </xsl:variable>

        <persons>
            <xsl:call-template name="serialize">
                <xsl:with-param name="set" select="msxsl:node-set($groups)/*"/>

                <xsl:with-param name="max-group-count" select="$max-count"/>
            </xsl:call-template>
        </persons>
    </xsl:template>

(rest is as original)

pgtips · October 2nd, 2003, 06:06 AM

Weird, I tried your modified version in XMLSpy and it worked just fine with MSXML3 and MSXML4, but it did crash using XML Spy's built-in engine (whatever that is). If I take out the msxsl:node-set() calls then it does indeed give the "expression must evaluate to a node-set" error.

I'll keep looking...

pgtips · October 2nd, 2003, 07:22 AM

Sorry, but I've had no luck reproducing your error. Since I'm lost as to why armen's version doesn't seem to work for you, the only thing I can think to help you is to go back and amend my original attempt to incorporate calculation of the max number, using that max to determine when to move position. Here is the new version which now works if numbers are missing from the sequence.

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" encoding="UTF-8"/>
  <xsl:variable name="numRecs" select="count(/persons/person)"/>
  <xsl:variable name="maxNum">
    <xsl:call-template name="getMax">
      <xsl:with-param name="nodes" select="/persons/person/number"/>
    </xsl:call-template>
  </xsl:variable>
  <xsl:key name="nodesByNumber" match="person" use="number"/>
  <xsl:template match="/">
    <persons>
      <xsl:call-template name="genOutput">
        <xsl:with-param name="num" select="1"/>
        <xsl:with-param name="posn" select="1"/>
        <xsl:with-param name="recCount" select="1"/>
      </xsl:call-template>
    </persons>
  </xsl:template>
  <xsl:template name="genOutput">

    <xsl:param name="num"/>

    <xsl:param name="posn"/>
    <xsl:param name="recCount"/>
    <xsl:choose>
      <xsl:when test="$recCount &gt; $numRecs">

      </xsl:when>
      <xsl:when test="$num &gt; $maxNum">
        <!-- if the max number is exceeded then
    move back to number 1 and increment the position -->
        <xsl:call-template name="genOutput">
          <xsl:with-param name="num" select="1"/>
          <xsl:with-param name="posn" select="$posn+1"/>
          <xsl:with-param name="recCount" select="$recCount"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:choose>
          <xsl:when test="key('nodesByNumber', $num)[$posn]">
            <!-- if a node with the given number and position exists, then
    copy it to result tree, move on to the next number, and increment recCount -->
            <xsl:copy-of select="key('nodesByNumber', $num)[$posn]"/>
            <xsl:call-template name="genOutput">
              <xsl:with-param name="num" select="$num+1"/>
              <xsl:with-param name="posn" select="$posn"/>
              <xsl:with-param name="recCount" select="$recCount+1"/>
            </xsl:call-template>
          </xsl:when>
          <xsl:otherwise>
            <!-- if a node with the given number and position doesn't exist, then
        just move on to the next number, without incrementing recCount -->
            <xsl:call-template name="genOutput">
              <xsl:with-param name="num" select="$num+1"/>
              <xsl:with-param name="posn" select="$posn"/>
              <xsl:with-param name="recCount" select="$recCount"/>
            </xsl:call-template>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  <xsl:template name="getMax">
    <xsl:param name="nodes"/>
    <xsl:choose>
      <xsl:when test="not($nodes)">NaN</xsl:when>
      <xsl:otherwise>
        <xsl:for-each select="$nodes">
          <xsl:sort data-type="number" order="descending"/>
          <xsl:if test="position() = 1">
            <xsl:value-of select="number(.)"/>
          </xsl:if>
        </xsl:for-each>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

hth
Phil

polecat · October 2nd, 2003, 08:06 AM

Wow, thats brilliant thanks!!

Its seems that MSXML 4 is causing my problems... using MSXML 3, both stylesheets work fine! So its all sorted, I can use MSXML 3 no problem. (wish I'd tried that earlier!)

pgtips · October 2nd, 2003, 08:32 AM

strange that it works with MSXML 3 but not 4. Knowing Microsoft, there's probably a service pack that will fix it for you. Not sure what SP number they're up to at the moment for MSXML4.

Anyway, at least you have a working solution to your problem.:D It was an interesting exercise.

armmarti · October 2nd, 2003, 08:35 AM

O la la... I've missed the most interesting points in this thread :) Sorry guys, I was(am) busy, and couldn't look at the forum, but it's fine that you've found the solution.
Concerning the RTF to nodeset conversion: XSLT 2.0 promises that any RTF(more precisely, temporary tree) will be represented as a root node of the variable's content-tree (and the node can be later processed as any XML document node) and we'll finally get rid of that annoying conversions. I agree with pgtips that the problem is in that conversion.

Regards,
Armen