Problem transforming unbounded types.

amac · July 7th, 2006, 04:30 PM

I'm having some problems transforming an XML file into HTML.

An example of the XML:

Code:

<transmissionPolicy><methodPolicy>
        <method>
            <className>X</className>
            <argumentType>Z1</argumentType>
            <argumentType>Z2</argumentType>
            <argumentType>Z3</argumentType>
        </method>
    </methodPolicy>
</transmissionPolicy>

The problem comes when I try to list the values in 'argumentType'. Only the first value will display. The potential number of argument types is unbounded.

The XSLT i am using looks like this:

Code:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="html"/>

  <xsl:template match="transmissionPolicy">
    <html>
      <body>
        <h3>Method Policy</h3>
        <xsl:apply-templates/>
      </body>
    </html>
  </xsl:template>

  <xsl:template match="methodPolicy">

    <h4>Method</h4>
    <table border="0">
      <xsl:apply-templates/>
    </table>

  </xsl:template>

  <xsl:template match="method">
    <tr>
      <td>
      <xsl:value-of select="argumentType"/>
      </td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

Does anyone know how I can correctly disply all 'argumentTypes'?

Any help is much appreciated.

joefawcett · July 7th, 2006, 04:45 PM

xsl:value-of, in version 1.0, gives the value of the first node you select. You don't say what you actually want to show but perhaps:

Code:

  <xsl:template match="method">
    <tr>
      <xsl:apply-templates select="argumentType"/>
    </tr>
  </xsl:template>
  <xsl:template match="argumentType">
    <td>
      <xsl:value-of select="."/>
    </td>
  </xsl:template>

--

Joe (Microsoft MVP - XML)

mhkay · July 7th, 2006, 04:53 PM

Replace

<xsl:value-of select="argumentType"/>

by

<xsl:for-each select="argumentType">
<xsl:value-of select="."/>
</xsl:for-each>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

amac · July 8th, 2006, 04:18 AM

Thanks, that works perfectly.

Quote:

quote:Originally posted by mhkay
Replace

<xsl:value-of select="argumentType"/>

by

<xsl:for-each select="argumentType">
<xsl:value-of select="."/>
</xsl:for-each>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference