I'm using Saxon 8.7 to solve the following problem:

XML Source:
<root>
    <heading1>
        <plain>plain text</plain>>
        <plain>plain text</plain>
        <plain>plain text</plain>
        <plain>plain text</plain>
        <plain>plain text</plain>
        <jtext>jtext jtext jtext jtext jtext</jtext>
        <jtext>jtext jtext jtext jtext jtext</jtext>
        <jheader>a jkopjheader</jheader>
        <jtext>jtext jtext jtext jtext jtext</jtext>
        <jtext>jtext jtext jtext jtext jtext</jtext>
        <jtext>jtext jtext jtext jtext jtext</jtext>
        <jtext>jtext jtext jtext jtext jtext</jtext>
        <btext>my btext</btext>
        <plain>plain text</plain>
        <plain>plain text</plain>
        <plain>plain text</plain>
        <plain>plain text</plain>
        <plain>plain text</plain>
        <jheader>a jheader</jheader>
        <jtext>jtext jtext jtext jtext jtext</jtext>
        <jtext>jtext jtext jtext jtext jtext</jtext>
        <jtext>jtext jtext jtext jtext jtext</jtext>
        <jtext>jtext jtext jtext jtext jtext</jtext>
        <btext>my btext</btext>
    </heading1>
</root>

Desired output:
<root>
    <heading1>
        <plaingroup>
            <plain>plain text</plain>
            <plain>plain text</plain>
            <plain>plain text</plain>
            <plain>plain text</plain>
            <plain>plain text</plain>
        </plaingroup>
        <jgroup>
            <jtext>jtext jtext jtext jtext jtext</jtext>
            <jtext>jtext jtext jtext jtext jtext</jtext>
        </jgroup>
        <jgroup>
            <jheader>a jheader</jheader>
            <jtext>jtext jtext jtext jtext jtext</jtext>
            <jtext>jtext jtext jtext jtext jtext</jtext>
            <jtext>jtext jtext jtext jtext jtext</jtext>
            <jtext>jtext jtext jtext jtext jtext</jtext>
            <btext>my btext</btext>
        </jgroup>
        <plaingroup>
            <plain>plain text</plain>
            <plain>plain text</plain>
            <plain>plain text</plain>
            <plain>plain text</plain>
            <plain>plain text</plain>
        </plaingroup>
        <jgroup>
            <jheader>a jheader</jheader>
            <jtext>jtext jtext jtext jtext jtext</jtext>
            <jtext>jtext jtext jtext jtext jtext</jtext>
            <jtext>jtext jtext jtext jtext jtext</jtext>
            <jtext>jtext jtext jtext jtext jtext</jtext>
            <btext>my btext</btext>
        </jgroup>
    </heading1>
</root>

My stylesheet until now:
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:strip-space elements="*"/>

    <xsl:template match="root">
        <xsl:element name="{name()}">
            <xsl:apply-templates/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="heading1">
        <xsl:element name="{name()}">
            <xsl:for-each-group select="*" group-adjacent="self::*">
                <xsl:choose>
                    <xsl:when test="self::plain">
                        <plaingroup>
                            <xsl:for-each-group select="current-group()" group-adjacent="self::plain">
                                <xsl:copy-of select="current-group()"/>
                            </xsl:for-each-group>
                        </plaingroup>
                    </xsl:when>
                    <xsl:when test="self::jkop">
                        <jgroup>
                            <xsl:for-each-group select="current-group()" group-adjacent="self::jheader or self::jtext or self::btext">
                                <xsl:copy-of select="current-group()"/>
                            </xsl:for-each-group>
                        </jgroup>
                    </xsl:when>
                    <xsl:when test="self::jtext">
                        <jgroup>
                            <xsl:for-each-group select="current-group()" group-adjacent="self::jtext or self::btext">
                                <xsl:copy-of select="current-group()"/>
                            </xsl:for-each-group>
                        </jgroup>
                    </xsl:when>
                    <xsl:when test="self::btext">
                        <jgroup>
                            <xsl:for-each-group select="current-group()" group-adjacent="self::jtext | self::btext">
                                <xsl:copy-of select="current-group()"/>
                            </xsl:for-each-group>
                        </jgroup>
                    </xsl:when>
                    <xsl:otherwise>
                        <unknown>
                            <xsl:copy-of select="current-group()"/>
                        </unknown>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each-group>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>


The key problem for me is to understand the group-adjacent attribute. I can't figure out how it exactly works. Does anyone has a small sample or hint to put me in the right direction?

Thanks & Regards,

Geurt Lagemaat.

group-adjacent defines the value that adjacent things have in common if they are to go in the same group. In your case, for the most part you are grouping elements that have the same name, that is:

group-adjacent="node-name(.)"

Writing group-adjacent="self::*" (or just group-adjacent=".") would be appropriate if it's the value (content) of the elements that matters rather than their name.

I don't know how completely your example describes the problem, but I think I'd be inclined to tackle it using group-starting-with. Something like:

group-starting-with="plain[not(preceding-sibling::*[1][self::plain])] | jheader | jtext[not(preceding-sibling::*[1][self::jtext or self::jheader])]"

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Thank you for you’re help. I didn’t read you’re book to well… I was thinking that I could use the group-adjacent attribute as some sort selection of element names that make up a group. You put me in the right direction with the group-starting-with attribute. My stylesheet now looks like:

<?xml version="1.0"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:strip-space elements="*"/>

    <xsl:template match="root">
        <xsl:element name="{name()}">
            <xsl:apply-templates/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="heading1">
        <xsl:element name="{name()}">
            <xsl:for-each-group select="*" group-starting-with="plain[not(preceding-sibling::*[1][self::plain])] | jheader | jtext[not(preceding-sibling::*[1][self::jheader or self::jtext or self::btext])] | btext[not(preceding-sibling::*[1][self::jheader or self::jtext or self::btext])]">
                <xsl:choose>
                    <xsl:when test="self::plain">
                        <plaingroup>
                            <xsl:copy-of select="current-group()"/>
                        </plaingroup>
                    </xsl:when>
                    <xsl:otherwise>
                        <jgroup>
                            <xsl:copy-of select="current-group()"/>
                        </jgroup>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each-group>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>


and is working correctly.

Thanks again, Geurt Lagemaat