Plase, why cannot I add attribute ?
line : <xsl:attribute name="onclick">__Goto(<xsl:value-of select="@id"/>, <xsl:value-of select="ancestor::cat[1]/@id"/>);</xsl:attribute>

when I make transformation, there is no OnClick Attribute.



<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="html"/>

<xsl:param name="catId"/>
<xsl:param name="subCatId"/>

<xsl:template match="/">

<TABLE cellpadding="0" cellspacing="0" border="0" class="catMenu">
<xsl:for-each select="//cats/cat">
<TR onmouseover="__MOn(this);" onmouseout="__MOff(this);">
<TD class="catName">
<xsl:attribute name="onclick">__Show(<xsl:value-of select="@id"/>);</xsl:attribute>
<xsl:value-of select="@name"/>
</TD>
</TR>

<TR class="sCatContainerH">
<xsl:if test="@id=$catId">
<xsl:attribute name="class">sCatContainerV</xsl:attribute>
</xsl:if>
<xsl:attribute name="id">cat<xsl:value-of select="@id"/></xsl:attribute>
<TD>
    <TABLE class="subCats" cellpadding="0" cellspacing="0" border="0" width="100%">
    <TR>
    <TD class="sCatName" onmouseover="__MOn(this);" onmouseout="__MOff(this);">Today events
    <xsl:attribute name="id">catProba</xsl:attribute>
    <xsl:attribute name="onclick">__Goto(0, <xsl:value-of select="ancestor::cat[1]/@id"/>);</xsl:attribute>
    </TD></TR>
    <xsl:for-each select="subCat">

        <TR>
        <TD class="sCatName" onmouseover="__MOn(this);" onmouseout="__MOff(this);">
        <xsl:attribute name="onclick">__Goto(<xsl:value-of select="@id"/>, <xsl:value-of select="ancestor::cat[1]/@id"/>);</xsl:attribute>
        <xsl:if test="@id=$subCatId"><xsl:attribute name="style">font-weight:bold</xsl:attribute></xsl:if>
        <xsl:value-of select="."/>
        </TD>
        </TR>
    </xsl:for-each>
    </TABLE>
</TD>
</TR>
</xsl:for-each>
</TABLE>

</xsl:template>

</xsl:stylesheet>

Can you show a sample of the source XML?

--

Joe (Microsoft MVP - XML)

Presumably your stylesheet doesn't find what it's looking for in the input document. Without seeing the input document, it's impossible to debug it for you.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

 >>Presumably your stylesheet doesn't find what it's looking for in
 >>the input document. Without seeing the input document, it's
 >>impossible to debug it for you.

I made amistake in my privious email : I din not want to add two attributes, only one (bold)
<xsl:attribute name="id">catProba</xsl:attribute>
<xsl:attribute name="onclick">__Goto(0, <xsl:value-of select="ancestor::cat[1]/@id"/>);</xsl:attribute>

But if I try to add following :
<xsl:attribute name="onclick">__Goto(0,9);</xsl:attribute>
or
<xsl:attribute name="id">catProba</xsl:attribute>
It doesn't work too.

As I say, I can't debug it with seeing the source document. Showing me different code from the code that you were actually running also makes it a wee bit more difficult to find your bugs.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

I'm sending xml and xslt :

<?xml version="1.0" encoding="UTF-8"?>
<cats>
<cat id="1" name="American Football">
<subCat id="1">CFL</subCat>
<subCat id="2">NFL</subCat>
</cat>
<cat id="2" name="Baseball">
<subCat id="3">Japanese Baseball</subCat>
<subCat id="4">MLB</subCat>
<subCat id="5">World Baseball Classics</subCat>
</cat>
</cats>



<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="html"/>

<xsl:param name="catId"/>
<xsl:param name="subCatId"/>

<xsl:template match="/">

<TABLE cellpadding="0" cellspacing="0" border="0" class="catMenu">
<xsl:for-each select="//cats/cat">
<TR onmouseover="__MOn(this);" onmouseout="__MOff(this);">
<TD class="catName">
<xsl:attribute name="onclick">__Show(<xsl:value-of select="@id"/>);</xsl:attribute>
<xsl:value-of select="@name"/>
</TD>
</TR>

<TR class="sCatContainerH">
<xsl:if test="@id=$catId">
<xsl:attribute name="class">sCatContainerV</xsl:attribute>
</xsl:if>
<xsl:attribute name="id">cat<xsl:value-of select="@id"/></xsl:attribute>
<TD>
    <TABLE class="subCats" cellpadding="0" cellspacing="0" border="0" width="100%">
    <TR>
    <TD class="sCatName" onmouseover="__MOn(this);" onmouseout="__MOff(this);">Today events
     <xsl:attribute name="onclick">__Goto(<xsl:value-of select="@id"/>, <xsl:value-of select="ancestor::cat[1]/@id"/>);</xsl:attribute>
    </TD></TR>
    <xsl:for-each select="subCat">

        <TR>
        <TD class="sCatName" onmouseover="__MOn(this);" onmouseout="__MOff(this);">
        <xsl:attribute name="onclick">__Goto(<xsl:value-of select="@id"/>, <xsl:value-of select="ancestor::cat[1]/@id"/>);</xsl:attribute>
        <xsl:if test="@id=$subCatId"><xsl:attribute name="style">font-weight:bold</xsl:attribute></xsl:if>
        <xsl:value-of select="."/>
        </TD>
        </TR>
    </xsl:for-each>
    </TABLE>
</TD>
</TR>
</xsl:for-each>
</TABLE>

</xsl:template>

</xsl:stylesheet>

Saxon gives this error message:

Error on line 21 of file:/c:/temp/test.xsl:
  XTDE0410: Cannot create an attribute node after creating a child of the containing element

XSLT 1.0 processors are allowed to ignore this error and "recover" by ignoring the xsl:attribute instruction. I expect you are using such a processor.

What's wrong is this:

    <TD class="sCatName">
       Today events
       <xsl:attribute name="onclick">__Goto...;</xsl:attribute>
    </TD>

where you create the child element of the TD before creating its attribute.

Incidentally, I would have spotted this far earlier if you had taken the trouble to lay out your code more neatly.

This becomes a hard error in XSLT 2.0 that all processors must report. Saxon actually detects this particular instance at compile time.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference