Sum up value of all entity

ksafong · October 27th, 2006, 08:51 PM

Dear all,

I have a xml like this:

<?xml version="1.0" encoding="UTF-8"?>
<tropicalStorm>
    <name>Maria</name>
    <rainfall>
        <station>
            <location>Hong Kong Observatory</location>
            <amount date="2006-05-16">1.6</amount>
            <amount date="2006-05-17">15.0</amount>
        </station>
        <station>
            <location>Mid Levels</location>
            <amount date="2006-05-15">0.0</amount>
            <amount date="2006-05-16">2.0</amount>
            <amount date="2006-05-17">10.0</amount>
            <amount date="2006-05-18">0.0</amount>
        </station>
        <station>
            <location>Shau Kei Wan</location>
            <amount date="2006-05-15">0.0</amount>
            <amount date="2006-05-16">2.5</amount>
            <amount date="2006-05-17">10.0</amount>
            <amount date="2006-05-18">1.0</amount>
        </station>
    </rainfall>
</tropicalStorm>

I want to sum up the total rainfall amount in html like this:

-------------------------------
|Station |Total|
------------------------|-----|
|Hong Kong Observatory | 16.6|
------------------------|-----|
|Mid Levels | 12.0|
------------------------|-----|
|Shau Kei Wan | 13.5|
-------------------------------

So how to sum up the value of the "amount" entity? Please help!!! Thx a lot!

mhkay · October 28th, 2006, 03:43 AM

First, get your terminology right. It's an element, not an entity. You won't be able to find the right entry in the index of a book, or the right information on Google, if you use the wrong terminology.

Second, use the sum function: sum(amount).

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

joefawcett · October 28th, 2006, 03:47 AM

You need to output one row for each station so for each station you need sum(amount):

Code:

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="/">
    <html>
      <body>
        <table>
          <caption>
            Rainfall by Station during '<xsl:value-of select="*/name"/>'
          </caption>
          <thead>
            <tr>
              <th>Station</th>
              <th>Rainfall</th>
            </tr>
          </thead>
          <tbody>
            <xsl:apply-templates select="*/rainfall/station"/>
            <tr>
              <td>ALL</td>
              <td>
                <xsl:value-of select="sum(*/rainfall/station/amount)"/>
              </td>
            </tr>
          </tbody>
        </table>
      </body>
    </html>
  </xsl:template>

  <xsl:template match="station">
    <tr>
      <td>
        <xsl:value-of select="location"/>
      </td>
      <td>
        <xsl:value-of select="sum(amount)"/>
      </td>
    </tr>
  </xsl:template>
</xsl:stylesheet>

--

Joe (Microsoft MVP - XML)