Firstly, there's a missing </fact> end tag around line 1200 of your XML input. Your stylesheet will never work if the input isn't well-formed XML. (Also note, if you're asked for a complete working sample, it's best to cut it down to the minimum size that actually demonstrates the problem.)

With that fixed, the stylesheet doesn't output "nothing", it outputs a lot of empty table cells like this:

<td align="center"></td>

That immediately tells you that the problem lies in the code

                    <td align="center">
                       <xsl:value-of select="value"/>
                    </td>

- specifically it means that select="value" is selecting nothing. That's because your context node is a fact, and a fact element has no child called 'value'.

I could change it to

select="slot[name='rank']/value"

and you would then get some output. But it wouldn't be the output you are looking for. You're outputting a td element here that isn't part of any tr.

I think what you probably want is this:

        <xsl:template match="rules">
          <tr bgcolor="#aaccdd">
            <th><h2>SNP rs number</h2></th>
            <th><h2>Rank Score</h2></th>
            <th><h2>Ranking Determination</h2></th>
          </tr>
          <xsl:for-each select="fact[name='MAIN::SNPRank']">
                 <xsl:sort select="slot[name='rank']/value" data-type="number" order="descending"/>
                 <tr>
                    <td align="center">
                       <xsl:value-of select="slot[name='id']/value"/>
                    </td>
                    <td align="center">
                       <xsl:value-of select="slot[name='rank']/value"/>
                    </td>
                    <td align="center">
                       <xsl:value-of select="slot[name='category']/value"/>
                    </td>
                 </tr>
          </xsl:for-each>
        </xsl:template>

or alternatively:

        <xsl:template match="rules">
          <tr bgcolor="#aaccdd">
            <th><h2>SNP rs number</h2></th>
            <th><h2>Rank Score</h2></th>
            <th><h2>Ranking Determination</h2></th>
          </tr>
          <xsl:for-each select="fact[name='MAIN::SNPRank']">
                 <xsl:sort select="slot[name='rank']/value" data-type="number" order="descending"/>
                 <tr>
                    <xsl:for-each select="slot">
                    <td align="center">
                       <xsl:value-of select="value"/>
                    </td>
                    </xsl:for-each>
                 </tr>
          </xsl:for-each>
        </xsl:template>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

YAY!! Thank you so very much for your time and expertise. Your solution worked! Thank you again :) Did I mention thank you...

:D