I have a source XML document to transform (from a 3rd party) like this

<SOSA xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns="http://www.nonesuch.com/ns/namespace/v2">
    <Header xmlns="">
        <Version>2.0</Version>
        <Mode>TEST</Mode>
    </Header>
    <Authentication xmlns="">
        <Username/>
        <Password/>
    </Authentication>
    <SOR xmlns="">
        <Reference>E20150645</Reference>
        <AllocatedBy>001</AllocatedBy>
    </SOR>
    <SOR xmlns="">
        <Reference>86072||25671</Reference>
        <AllocatedBy>002</AllocatedBy>
    </SOR>
    <SOR xmlns="">
        <Reference>79376</Reference>
        <AllocatedBy>003</AllocatedBy>
    </SOR>
</SOSA>

As you can see it has a default namespace but also has xmlns="" declared in various elements. I think I know why the document is like this but I can't work out how my stylesheet should be written.

My xsl looks like this at the moment but this doesn't find SOR.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions" xpath-default-namespace="http://www.nonesuch.com/ns/namespace/v2">
    <xsl:template match="/SOSA">
        <Data>
            <Header>
                <SenderID>xxx</SenderID>
                <xsl:for-each select="SOR">
                    <xsl:if test="AllocatedBy='001'">
                        <TargetID>
                            <xsl:value-of select="Reference"/>
                        </TargetID>
                    </xsl:if>
                </xsl:for-each>
            </Header>
        </Data>
    </xsl:template>
</xsl:stylesheet>

How do I tell the XSL to use xmlns="" for these elements?

Hope this makes sense and TIA

On the whole I'd suggest that if some of your source elements are in a namespace and others aren't, then it's better to bind an explicit prefix in the stylesheet and use it whenever you refer to an element in a namespace, for example <xsl:template match="/p1:SOSA">. That's the only way to do it in XSLT 1.0.

However, if you want to use xpath-default-namespace you can, for example you can write

 <xsl:for-each select="SOR" xpath-default-namespace="">

which will override the value used at the xsl:stylesheet level.


Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Thanks for the help - took the <xsl:for-each select="SOR" xpath-default-namespace=""> route.

Thanks again

Stewart