format-number function problem

jeffbk · May 2nd, 2007, 03:41 PM

Hi all

i am kind of new to xslt and i am having problems with outputing one of my outputs. my xml file consists of invoices and i have to calculate the sub total for each invoice which i am able to do.

the problem is when i try to format the output to include the dollar currency. the output fails and gives NaN

i used the following peice of code to format my output:

<xsl:value-of select="format-number((($node/quantity*$node/unitPrice) - (($node/discount div 100) * $node/unitPrice *$node/quantity)) + $sum-of-rest,'$####0.00#')"/>

it gives me an output of Nan. But if i dont include the dollar sign. the proper output is given for example it outputs 300.00 but i would lke the output to beign soemthing like this $300.00.

so i dont know what exactky is wrong. i would really appreciate anyones help

kind regards

jeff

bonekrusher · May 2nd, 2007, 03:56 PM

The $ sign in XSLT means that is a variable. For example

<xsl:variable name="myvar">Hello</xsl:variable>

to use:

<xsl:value-of select="$myvar"/>

mhkay · May 2nd, 2007, 04:17 PM

format-number() in XSLT 1.0 isn't very well specified. The spec says that the format picture is interpreted as in the DecimalFormat class in JDK 1.1 (there's actually a link to the Sun web site which is now broken). Many Java-based XSLT processors use the implementation of DecimalFormat in whatever version of Java they happen to be running on, which is of course incorrect, because it has changed since 1.1; and one of the things that has changed is the handling of currency signs. Non-Java-based processors do their best to emulate the Java 1.1 behaviour, but that's not easy either as many aspects of the behaviour are left unspecified in JDK 1.1 (though in some cases later releases have improved documentation).

It's hard to tell without pulling the JDK 1.1 spec out of archive storage exactly what the correct behaviour here is, and even if you did, it probably wouldn't give you a clear answer. Simplest solution is to take the "$" out of your picture, and add it into the output using concat().

This is all assuming you are using an XSLT 1.0 processor. XSLT 2.0 has it's own specification of format-number() with no dependency on the JDK specification.

bonekrusher's response is quite irrelevant, by the way. $ does introduce an XPath variable, but not when it's within a string literal.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

bonekrusher · May 2nd, 2007, 05:30 PM

Thanks for the correction :)

jeffbk · May 3rd, 2007, 04:55 PM

HI guys thanks for your inputs. oh Michael i tried concatenating the dollar sign with the output value but it still gives the NaN value. funny thing is that if i use the above format with the dollar sign to a a simple value such as that from an element it works fine. ii was wondering if there was any other way

mhkay · May 3rd, 2007, 05:07 PM

>it still gives the NaN value

In that case the dollar sign wasn't the problem.

What happens if you replace

<xsl:value-of select="format-number(X)"/>

with

<xsl:value-of select="X"/>

?

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

mhkay · May 4th, 2007, 01:50 AM

Please produce a cut-down example that other people can run, one with no dependencies on other files, and preferably with all those confusing commented-out lines removed.

It's also useful to say what processor you are using, given that I explained earlier that the problem might be system-dependent. (It's even more useful to try it yourself on more than one processor and report whether they all give the same result...)

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

jeffbk · May 4th, 2007, 05:32 PM

hi i am sorry for giving such a huge example. anyway i am using xslt version 1 and i have also tried using xslt version 2 but i still get the same output NaN. the code i have given below is a sample version.

the xslt code is:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="2.0">

<xsl:template match="/">
  <html>
    <head>
      <title>Invoice</title>
    </head>
    <body>
      <h1>Invoice</h1>

      <table border="1" style="text-align: center">
        <tr>
          <th>Description</th>
          <th>Quantity</th>
          <th>Unit price</th>
          <th>Subtotal</th>
        </tr>
        <xsl:for-each select="invoice/item">
          <tr>
            <td><xsl:value-of select="description"/></td>
            <td><xsl:value-of select="qty"/></td>
            <td><xsl:value-of select="unitPrice"/></td>
            <td><xsl:value-of select="qty * unitPrice"/></td>
          </tr>
        </xsl:for-each>
        <tr>
          <th colspan="3">Total</th>
          <th>

            <xsl:call-template name="add">
              <xsl:with-param name="node" select="invoice/item[1]"/>
            </xsl:call-template>
          </th>
        </tr>
      </table>
    </body>
  </html>
</xsl:template>


<xsl:template name="add">
  <xsl:param name="node" select="."/>
  <xsl:variable name="sum-of-rest">
    <xsl:choose>
      <xsl:when test="$node/following-sibling::item">
        <xsl:call-template name="add">
          <xsl:with-param name="node"
            select="$node/following-sibling::item[1]"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>0</xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <xsl:value-of select="format-number((($node/qty)*($node/unitPrice) + $sum-of-rest),'$##0.00')"/>
</xsl:template>

</xsl:stylesheet>

the xml file is as follows:

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet type="text/xsl" href="invoice-noext.xsl"?>
<invoice>
  <item>
    <description>Pilsner Beer</description>
    <qty>6</qty>
    <unitPrice>1.69</unitPrice>
  </item>
  <item>
    <description>Sausage</description>
    <qty>3</qty>
    <unitPrice>0.59</unitPrice>
  </item>
  <item>
    <description>Portable Barbecue</description>
    <qty>1</qty>
    <unitPrice>23.99</unitPrice>
  </item>
  <item>
    <description>Charcoal</description>
    <qty>2</qty>
    <unitPrice>1.19</unitPrice>
  </item>
</invoice>

kind regards

Jeff

mhkay · May 5th, 2007, 03:20 AM

Running this through Saxon 8.9, I get:

Validation error on line 48 of file:///c:/temp/test.xsl:
Cannot convert string "$2.38" to a double

The line number isn't particularly helpful, but it shows where the problem lies: you are formatting the intermediate results of the calculation, including a "$" sign in the value, and then trying to convert the formatted results back to a double. Under XSLT 2.0 this fails (or should fail, if it doesn't then your processor isn't conformant). Under 1.0 it gives NaN.

Change the computation so it only applies the formatting (and rounding) to the final result, not to intermediate results.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference