I am using the transform below to convert an ADO persisted XML to ExcelXML. The conversion is done correctly except the following minor issue.

The output from <xslt:template match="z:row"> block at the bottom generates this --> <Row ss:Height="15" xmlns="">
instead of --> <Row ss:Height="15">

Where is this xmlns="" coming from? Any idea how to fix it


My Transform.
<?xml version="1.0" encoding="UTF-8"?>
<!--
This stylesheet is used to transform ADO recordset to Excel XML. By default, the
sheet converts the recordset to a complete Excel XML workbook
-->

<xslt:stylesheet xmlns:xslt="http://www.w3.org/1999/XSL/Transform"
                xmlns:rs="urn:schemas-microsoft-com:rowset"
                xmlns:s="uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882"
                xmlns:dt="uuid:C2F41010-65B3-11d1-A29F-00AA00C14882"
                xmlns:z="#RowsetSchema"
                xmlns:ms="urn:schemas-microsoft-com:xslt"
    xmlns:o="urn:schemas-microsoft-com:office:office"
    xmlns:x="urn:schemas-microsoft-com:office:excel"
                xmlns:ss="urn:schemas-microsoft-com:office:spreadsheet"
                version="1.0"
                exclude-result-prefixes="rs s dt z o x ss">

    <xslt:output method="xml" omit-xml-declaration="no" indent="yes" encoding="UTF-8"/>
  <xslt:template match="/">

    <Workbook xmlns="urn:schemas-microsoft-com:office:spreadsheet"
               xmlns:o="urn:schemas-microsoft-com:office:office"
               xmlns:x="urn:schemas-microsoft-com:office:excel"
               xmlns:ss="urn:schemas-microsoft-com:office:spreadsheet"
               xmlns:html="http://www.w3.org/TR/REC-html40">
            <Styles>
                <Style ss:ID="Default" ss:Name="Normal">
                    <Alignment ss:Vertical="Bottom"/>
                    <Borders/>

                    <Interior/>
                    <NumberFormat/>
                    <Protection/>
                </Style>
                <Style ss:ID="AltItem">
                    <Alignment ss:Vertical="Top" ss:WrapText="1"/>
                    <Borders>
                        <Border ss:Position="Bottom" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                        <Border ss:Position="Left" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                        <Border ss:Position="Right" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                        <Border ss:Position="Top" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                    </Borders>

                    <Interior/>
                </Style>
                <Style ss:ID="Header">
                    <Alignment ss:Horizontal="Center" ss:Vertical="Top" ss:WrapText="1"/>
                    <Borders>
                        <Border ss:Position="Bottom" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                        <Border ss:Position="Left" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                        <Border ss:Position="Right" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                        <Border ss:Position="Top" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                    </Borders>

                    <Interior ss:Color="#4A3C8C" ss:Pattern="Solid"/>
                </Style>
                <Style ss:ID="Item">
                    <Alignment ss:Vertical="Top" ss:WrapText="1"/>
                    <Borders>
                        <Border ss:Position="Bottom" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                        <Border ss:Position="Left" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                        <Border ss:Position="Right" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                        <Border ss:Position="Top" ss:LineStyle="Continuous" ss:Weight="1" ss:Color="#C0C0C0"/>
                    </Borders>

                    <Interior ss:Color="#CCCCFF" ss:Pattern="Solid"/>
                </Style>
            </Styles>
            <DocumentProperties xmlns="urn:schemas-microsoft-com:office:office">
                <Author>Exported from TopTraders Web Application</Author>
                <Created>2003-04-22T13:43:53Z</Created>
                <Version>1.0</Version>
            </DocumentProperties>



      <Worksheet ss:Name="Sheet">
        <Table>

            <Row ss:Height="15">
              <xslt:for-each select="/xml/s:Schema/s:ElementType[@name='row']/s:AttributeType">
                <xslt:sort select="@name" />
                <Cell ss:StyleID="Header">
                  <Data ss:Type="String">
                    <xslt:value-of select="@name" />
                      </Data>
                </Cell>
              </xslt:for-each>
            </Row>


            <xslt:apply-templates select="/xml/rs:data/z:row">

            </xslt:apply-templates>
        </Table>
      </Worksheet>

        </Workbook>
  </xslt:template>


  <xslt:template match="z:row">
        <Row ss:Height="15">
      <xslt:variable name="current_row" select="." />
      <xslt:for-each select="/xml/s:Schema/s:ElementType[@name='row']/s:AttributeType">
        <xslt:sort select="@name" />
        <xslt:variable name="attrName" select="@name" />
                        <Cell ss:StyleID="Item">
                            <Data ss:Type="String">
            <xslt:choose>
              <xslt:when test="s:datatype/@dt:type='dateTime'">
                <xslt:value-of select="ms:format-date($current_row/@*[name()=$attrName],'MM/dd/yyyy')" />
              </xslt:when>
              <xslt:otherwise>
                <xslt:value-of select="$current_row/@*[name()=$attrName]" />
              </xslt:otherwise>
            </xslt:choose>
                            </Data>
                        </Cell>
      </xslt:for-each>
        </Row>
  </xslt:template>
</xslt:stylesheet>

The following defines the default namespace for the Workbook element: <Workbook xmlns="urn:schemas-microsoft-com:office:spreadsheet">

However the <Row> element in the next template has a blank default namespace, so when embedded inside th Workbook output element the default namespace is made explicit by adding the xmlns="".

Either add xmlns="urn:schemas-microsoft-com:office:spreadsheet" to the Row element, or move it up to the xsl:stylesheet element.



/- Sam Judson : Wrox Technical Editor -/

If you generate elements with the right names (that is, namespace plus local name) then the namespace declarations will look after themselves. Your problem is that you wanted the Row element to be in a namespace, but you've generated it to be in no namespace. Its namespace is determined by the instruction used to create it - it won't automatically go in the same namespace as its parent element.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Thanks all for the help. I was under the assumption that the subsequent templates inherit the name space but I guess I was wrong.

Regards,

The scope of namespace declarations is as defined in XML: it's based on the static lexical XML hierarchy of your stylesheet. It doesn't follow the dyamic call sequence. If you want to declare a namespace that applies to all your templates, put it on the xsl:stylesheet element.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference